proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

5 files changed, 199 insertions, 0 deletions

diff --git a/media-libs/gst-plugins-bad/Manifest b/media-libs/gst-plugins-bad/Manifest
new file mode 100644
index 000000000000..07a0b18d41b7
--- /dev/null
+++ b/media-libs/gst-plugins-bad/Manifest
@@ -0,0 +1,4 @@
+DIST gst-plugins-bad-0.10.23-h264-patches.tar.xz 5284 SHA256 40890e4d7792d1b4e18c21204be57d71c34a9add20ef84f8de88c4037ba90858 SHA512 528ed30edb544dd970047fd4b0f05bf75f9f49f07a8118f805430c56c3ec75643013799491aeba70c62cb0343cd3e72758bf5c167d00e90a6a3f13857e4860e1 WHIRLPOOL f48af056d50df855e1281d3c1026c420f1158c3a007416f54bd690ce781089bacf71f0c6a90cece7bb64341c450fb9f6a6bab9a41cf9bd893c96440a0be1c33c
+DIST gst-plugins-bad-0.10.23.tar.xz 3155044 SHA256 03cf0786391c64625569072e904082a08861f05a63d64b2f8e8dad3f26d81bf9 SHA512 6437dd12707ef29651f4014b54612cf2a3a42ed4e05a1c5f4a432d80e27efd2abc0df891ebcfdc9e7b2cf9f71a15b88e48b3aa6db24a178ed6de3b1bdf4c3dc4 WHIRLPOOL dd657100909c32ab75cb8aada8db24d68ddf7a10dc0eb055982d7e4d9ae7a50c364eeac9017cea8b176734fc09cf7f8e4e8f52d24e3173806633ddb8a7acd93c
+DIST gst-plugins-bad-1.2.4.tar.xz 3272824 SHA256 984c133ec9d5d705e313d9e2bbd1472b93c6567460602a9a316578925ffe2eca SHA512 4344dedb899cdc0e3bf36a3b5dd36c6091e2e2f2a7440e3831cebbd9b4463f89cc4bc2d589b0c2c806bcaeb1864a49b3c9e0e3bedc051f1f46e09a8f131f0aa9 WHIRLPOOL 98bce50e7018d7c8d442bf8c7f26f14bd719a8af5af0fde39841c4282a9e4edfeefe06ab10797826cf9b876e173dafcf2e2df86408c373e6c4d8902072cf393c
+DIST gst-plugins-bad-1.4.5.tar.xz 3824936 SHA256 152fad7250683d72f9deb36c5685428338365fe4a4c87ffe15e38783b14f983c SHA512 65d6be58957b1329420611b8e6f1eb9869420745d9165047631cdf9e45083605f37dcfaf68a288fe4252f1b3543f7f70ded9c12eab2e0ac4ac9f4c4ce9eaac7a WHIRLPOOL f5ade3f101ca82b52e7145e5ac16f5c1ab5d042415ee7753586dc6ad0942467c4c5b5b4aa6b0bc44e1ebd9c40de1964df265aa41599cb692fd32aab2b6a7acf7
diff --git a/media-libs/gst-plugins-bad/gst-plugins-bad-0.10.23-r2.ebuild b/media-libs/gst-plugins-bad/gst-plugins-bad-0.10.23-r2.ebuild
new file mode 100644
index 000000000000..86033b7c8966
--- /dev/null
+++ b/media-libs/gst-plugins-bad/gst-plugins-bad-0.10.23-r2.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+
+GST_ORG_MODULE="gst-plugins-bad"
+inherit eutils flag-o-matic gstreamer
+
+DESCRIPTION="Less plugins for GStreamer"
+HOMEPAGE="http://gstreamer.freedesktop.org/"
+SRC_URI+=" http://dev.gentoo.org/~tetromino/distfiles/${PN}/${P}-h264-patches.tar.xz"
+
+LICENSE="LGPL-2"
+KEYWORDS="alpha amd64 arm hppa ia64 ppc ppc64 sparc x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux"
+IUSE="+orc"
+
+RDEPEND="
+	>=dev-libs/glib-2.34.3:2[${MULTILIB_USEDEP}]
+	>=media-libs/gst-plugins-base-0.10.36:${SLOT}[${MULTILIB_USEDEP}]
+	>=media-libs/gstreamer-0.10.36:${SLOT}[${MULTILIB_USEDEP}]
+	orc? ( >=dev-lang/orc-0.4.17[${MULTILIB_USEDEP}] )
+"
+DEPEND="${RDEPEND}"
+RDEPEND="${RDEPEND}
+	!<media-plugins/gst-plugins-farsight-0.12.11:${SLOT}"
+
+src_prepare() {
+	# Patches from 0.10 branch fixing h264 baseline decoding; bug #446384
+	epatch "${WORKDIR}/${P}-h264-patches"/*.patch
+}
+
+src_configure() {
+	strip-flags
+	replace-flags "-O3" "-O2"
+	filter-flags "-fprefetch-loop-arrays" # (Bug #22249)
+
+	multilib-minimal_src_configure
+}
+
+multilib_src_configure() {
+	gstreamer_multilib_src_configure \
+		$(use_enable orc) \
+		--disable-examples \
+		--disable-debug \
+		--disable-static
+}
+
+multilib_src_install_all() {
+	DOCS="AUTHORS ChangeLog NEWS README RELEASE"
+	einstalldocs
+	prune_libtool_files --modules
+}
diff --git a/media-libs/gst-plugins-bad/gst-plugins-bad-1.2.4-r1.ebuild b/media-libs/gst-plugins-bad/gst-plugins-bad-1.2.4-r1.ebuild
new file mode 100644
index 000000000000..d2e84b32cc9f
--- /dev/null
+++ b/media-libs/gst-plugins-bad/gst-plugins-bad-1.2.4-r1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+
+GST_ORG_MODULE="gst-plugins-bad"
+inherit eutils flag-o-matic gstreamer
+
+DESCRIPTION="Less plugins for GStreamer"
+HOMEPAGE="http://gstreamer.freedesktop.org/"
+
+LICENSE="LGPL-2"
+KEYWORDS="alpha amd64 arm hppa ia64 ppc ppc64 sparc x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux"
+IUSE="egl +introspection +orc vnc"
+
+# FIXME: we need to depend on mesa to avoid automagic on egl
+# dtmf plugin moved from bad to good in 1.2
+# X11 is automagic for now, upstream #709530
+RDEPEND="
+	>=dev-libs/glib-2.34.3:2[${MULTILIB_USEDEP}]
+	>=media-libs/gst-plugins-base-1.2:${SLOT}[${MULTILIB_USEDEP}]
+	>=media-libs/gstreamer-1.2:${SLOT}[${MULTILIB_USEDEP}]
+	egl? ( >=media-libs/mesa-9.1.6[egl,${MULTILIB_USEDEP}] )
+	introspection? ( >=dev-libs/gobject-introspection-1.31.1 )
+	orc? ( >=dev-lang/orc-0.4.17[${MULTILIB_USEDEP}] )
+
+	!<media-libs/gst-plugins-good-1.1:${SLOT}
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1.12
+"
+
+src_configure() {
+	strip-flags
+	replace-flags "-O3" "-O2"
+	filter-flags "-fprefetch-loop-arrays" # (Bug #22249)
+
+	multilib-minimal_src_configure
+}
+
+multilib_src_configure() {
+	gstreamer_multilib_src_configure \
+		$(multilib_native_use_enable introspection) \
+		$(use_enable orc) \
+		$(use_enable vnc librfb) \
+		--disable-examples \
+		--disable-debug \
+		--with-egl-window-system=$(usex egl x11 none)
+}
+
+multilib_src_install_all() {
+	DOCS="AUTHORS ChangeLog NEWS README RELEASE"
+	einstalldocs
+	prune_libtool_files --modules
+}
diff --git a/media-libs/gst-plugins-bad/gst-plugins-bad-1.4.5.ebuild b/media-libs/gst-plugins-bad/gst-plugins-bad-1.4.5.ebuild
new file mode 100644
index 000000000000..e1cc44b84504
--- /dev/null
+++ b/media-libs/gst-plugins-bad/gst-plugins-bad-1.4.5.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+GST_ORG_MODULE="gst-plugins-bad"
+
+inherit eutils flag-o-matic gstreamer
+
+DESCRIPTION="Less plugins for GStreamer"
+HOMEPAGE="http://gstreamer.freedesktop.org/"
+
+LICENSE="LGPL-2"
+KEYWORDS="alpha amd64 arm hppa ia64 ppc ppc64 sparc x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux"
+
+IUSE="X egl gles2 +introspection opengl +orc vnc wayland"
+REQUIRED_USE="
+	egl? ( !gles2 )
+	gles2? ( !egl !opengl )
+	opengl? ( X )
+	wayland? ( egl )
+"
+
+# dtmf plugin moved from bad to good in 1.2
+# X11 is automagic for now, upstream #709530
+RDEPEND="
+	>=dev-libs/glib-2.34.3:2[${MULTILIB_USEDEP}]
+	>=media-libs/gst-plugins-base-1.4:${SLOT}[${MULTILIB_USEDEP}]
+	>=media-libs/gstreamer-1.4:${SLOT}[${MULTILIB_USEDEP}]
+	introspection? ( >=dev-libs/gobject-introspection-1.31.1 )
+
+	egl? ( >=media-libs/mesa-9.1.6[egl,${MULTILIB_USEDEP}] )
+	gles2? ( >=media-libs/mesa-9.1.6[gles2,${MULTILIB_USEDEP}] )
+	opengl? (
+		>=media-libs/mesa-9.1.6[${MULTILIB_USEDEP}]
+		virtual/glu[${MULTILIB_USEDEP}] )
+	X? ( x11-libs/libX11[${MULTILIB_USEDEP}] )
+	wayland? ( dev-libs/wayland[${MULTILIB_USEDEP}] )
+
+	orc? ( >=dev-lang/orc-0.4.17[${MULTILIB_USEDEP}] )
+
+	!<media-libs/gst-plugins-good-1.1:${SLOT}
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1.12
+"
+
+src_configure() {
+	strip-flags
+	replace-flags "-O3" "-O2"
+	filter-flags "-fprefetch-loop-arrays" # (Bug #22249)
+
+	multilib-minimal_src_configure
+}
+
+multilib_src_configure() {
+	gstreamer_multilib_src_configure \
+		$(multilib_native_use_enable introspection) \
+		$(use_enable egl) \
+		$(use_enable gles2) \
+		$(use_enable opengl) \
+		$(use_enable opengl glx) \
+		$(use_enable orc) \
+		$(use_enable vnc librfb) \
+		$(use_enable X x11) \
+		$(use_enable wayland) \
+		--disable-examples \
+		--disable-debug \
+		--disable-cocoa \
+		--disable-wgl
+}
+
+multilib_src_install_all() {
+	DOCS="AUTHORS ChangeLog NEWS README RELEASE"
+	einstalldocs
+	prune_libtool_files --modules
+}
diff --git a/media-libs/gst-plugins-bad/metadata.xml b/media-libs/gst-plugins-bad/metadata.xml
new file mode 100644
index 000000000000..730ab73210a7
--- /dev/null
+++ b/media-libs/gst-plugins-bad/metadata.xml
@@ -0,0 +1,9 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<herd>gstreamer</herd>
+	<use>
+		<flag name="egl">Enable EGL support</flag>
+		<flag name="gles2">Enable GLES2 support</flag>
+	</use>
+</pkgmetadata>