media-libs/kvazaar: EAPI-6 bump and general cleanup

Package-Manager: Portage-2.3.52, Repoman-2.3.12
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

1 files changed, 20 insertions, 27 deletions

diff --git a/media-libs/kvazaar/kvazaar-9999.ebuild b/media-libs/kvazaar/kvazaar-9999.ebuild
index 17d2a2b7ecaf..46bae358eb20 100644
--- a/media-libs/kvazaar/kvazaar-9999.ebuild
+++ b/media-libs/kvazaar/kvazaar-9999.ebuild
@@ -1,45 +1,40 @@
-# Copyright 1999-2017 Gentoo Foundation
+# Copyright 1999-2018 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=5
-
-SCM=""
+EAPI=6
 
 GREATEST_PV="1.2.1"
 
-if [ "${PV#9999}" != "${PV}" ] ; then
-	SCM="git-r3"
+if [[ ${PV} = *9999 ]] ; then
+	inherit git-r3
 	EGIT_REPO_URI="https://github.com/ultravideo/kvazaar"
-fi
-
-inherit eutils multilib autotools multilib-minimal toolchain-funcs flag-o-matic ${SCM}
-
-DESCRIPTION="An open-source HEVC encoder"
-HOMEPAGE="http://ultravideo.cs.tut.fi/ https://github.com/ultravideo/kvazaar"
-
-if [ "${PV#9999}" = "${PV}" ] ; then
+else
 	SRC_URI="https://github.com/ultravideo/kvazaar/archive/v${PV}.tar.gz -> ${P}.tar.gz
 		test? ( https://github.com/silentbicycle/greatest/archive/v${GREATEST_PV}.tar.gz -> greatest-${GREATEST_PV}.tar.gz )"
-	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~x86"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
 fi
+inherit autotools flag-o-matic multilib-minimal toolchain-funcs
+
+DESCRIPTION="Open-source HEVC encoder"
+HOMEPAGE="http://ultravideo.cs.tut.fi/ https://github.com/ultravideo/kvazaar"
 
 LICENSE="LGPL-2.1"
 # subslot = libkvazaar major
 SLOT="0/4"
 IUSE="static-libs test"
-
-DEPEND=""
-RDEPEND="${DEPEND}"
 REQUIRED_USE="test? ( static-libs )"
 
 ASM_DEP=">=dev-lang/yasm-1.2.0"
-DEPEND="${DEPEND}
+RDEPEND=""
+DEPEND="${RDEPEND}
 	abi_x86_32? ( ${ASM_DEP} )
-	abi_x86_64? ( ${ASM_DEP} )"
+	abi_x86_64? ( ${ASM_DEP} )
+"
 
 src_prepare() {
+	default
 	eautoreconf
-	if use test && [ "${PV#9999}" = "${PV}" ]; then
+	if use test && [[ ${PV} != *9999 ]]; then
 		# https://bugs.gentoo.org/show_bug.cgi?id=595932
 		rmdir "${S}/greatest" || die
 		mv "${WORKDIR}/greatest-${GREATEST_PV}" "${S}/greatest" || die
@@ -49,13 +44,11 @@ src_prepare() {
 }
 
 multilib_src_configure() {
-	ECONF_SOURCE="${S}" \
-		econf \
-			--disable-werror \
-			--docdir "/usr/share/doc/${PF}" \
-			$(use_enable static-libs static)
+	ECONF_SOURCE="${S}" econf \
+		--disable-werror \
+		$(use_enable static-libs static)
 }
 
 multilib_src_install_all() {
-	find "${ED}" -name '*.la' -delete
+	find "${ED}" -name '*.la' -delete || die
 }