media-plugins/vdr-osdteletext: version bump to 0.9.8

new SRC_URI, new version

Package-Manager: Portage-3.0.14, Repoman-3.0.2
Signed-off-by: Martin Dummer <martin.dummer@gmx.net>
Closes: https://github.com/gentoo/gentoo/pull/19712
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

1 files changed, 46 insertions, 0 deletions

diff --git a/media-plugins/vdr-osdteletext/vdr-osdteletext-0.9.8.ebuild b/media-plugins/vdr-osdteletext/vdr-osdteletext-0.9.8.ebuild
new file mode 100644
index 000000000000..58ca915916a6
--- /dev/null
+++ b/media-plugins/vdr-osdteletext/vdr-osdteletext-0.9.8.ebuild
@@ -0,0 +1,46 @@
+# Copyright 2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit user-info vdr-plugin-2
+
+MY_P="vdr-plugin-osdteletext-${PV}"
+
+DESCRIPTION="VDR Plugin: Osd-Teletext displays the teletext/videotext on the OSD"
+HOMEPAGE="https://projects.vdr-developer.org/projects/plg-osdteletext https://github.com/vdr-projects/vdr-plugin-osdteletext/"
+SRC_URI="https://github.com/vdr-projects/vdr-plugin-osdteletext/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+ public-domain" #teletext2.ttf, not copyrightable
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+DEPEND="media-video/vdr"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}/${MY_P}"
+
+QA_FLAGS_IGNORED="
+	usr/lib/vdr/plugins/libvdr-.*
+	usr/lib64/vdr/plugins/libvdr-.*"
+
+src_install() {
+	vdr-plugin-2_src_install
+
+	insinto /etc/sudoers.d
+	insopts -m440
+	newins "${FILESDIR}/vdr-osdteletext.sudo" vdr-osdteletext
+
+	local vdr_user_home=$(egethome vdr)
+	insinto "${vdr_user_home}/.local/share/fonts/"
+	insopts -m444
+	doins teletext2.ttf
+	fowners -R vdr:vdr "${vdr_user_home}/.local"
+}
+
+pkg_postinst() {
+	elog "This ebuild has installed a special teletext font"
+	elog "named \"teletext2\""
+	elog "You may go to the plugin's setup menu and select"
+	elog "the font."
+}