proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 77 insertions, 0 deletions

diff --git a/media-sound/gejengel/gejengel-0.1.4-r1.ebuild b/media-sound/gejengel/gejengel-0.1.4-r1.ebuild
new file mode 100644
index 000000000000..db2015f6e1ff
--- /dev/null
+++ b/media-sound/gejengel/gejengel-0.1.4-r1.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=4
+inherit eutils multilib flag-o-matic
+
+DESCRIPTION="Lightweight audio player"
+HOMEPAGE="http://code.google.com/p/gejengel"
+SRC_URI="http://${PN}.googlecode.com/files/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 x86"
+IUSE="+alsa audioscrobbler debug dbus +ffmpeg flac libnotify mad openal pulseaudio syslog"
+
+RDEPEND="dev-cpp/gtkmm:2.4
+	dev-cpp/pangomm:1.4
+	media-libs/taglib
+	dev-db/sqlite:3
+	|| ( media-gfx/imagemagick[cxx]
+	media-gfx/graphicsmagick[imagemagick] )
+	mad? ( media-libs/libmad )
+	flac? ( media-libs/flac[cxx] )
+	ffmpeg? ( >=virtual/ffmpeg-9 )
+	audioscrobbler? ( >=media-libs/lastfmlib-0.4 )
+	dbus? ( dev-libs/dbus-glib )
+	libnotify? ( x11-libs/libnotify )
+	openal? ( media-libs/openal )
+	alsa? ( media-libs/alsa-lib )
+	pulseaudio? ( media-sound/pulseaudio )"
+DEPEND="${RDEPEND}
+	dev-libs/libxdg-basedir
+	dev-util/intltool
+	>=sys-devel/automake-1.11"
+
+DOCS=( AUTHORS ChangeLog README TODO )
+
+src_prepare() {
+	epatch "${FILESDIR}"/${P}-libnotify-0.7.patch \
+		"${FILESDIR}"/${P}-ffmpeg.patch \
+		"${FILESDIR}"/${P}-ffmpeg-1.patch \
+		"${FILESDIR}"/${P}-libav9.patch \
+		"${FILESDIR}"/${P}-ffmpeg2.patch
+	# Remove Vesion and Encoding from the desktop file
+	sed -i -e "/Version/d" -e "/Encoding/d" \
+		data/${PN}.desktop.in || die "sed failed"
+	append-cxxflags "-D__STDC_CONSTANT_MACROS"
+}
+
+src_configure() {
+	econf \
+		--disable-shared \
+		$(use_enable syslog logging) \
+		$(use_enable debug) \
+		$(use_enable openal) \
+		$(use_enable audioscrobbler lastfm) \
+		$(use_enable dbus) \
+		$(use_enable libnotify) \
+		$(use_enable mad) \
+		$(use_enable flac) \
+		$(use_enable ffmpeg) \
+		$(use_enable alsa) \
+		$(use_enable pulseaudio) \
+		--disable-unittests
+}
+
+src_compile() {
+	emake CXXFLAGS="${CXXFLAGS}"
+}
+
+src_install() {
+	default
+	# The libgejengel.a is used by the package when building but shouldn't end
+	# up in the installation target
+	rm -f "${ED}"usr/$(get_libdir)/libgejengel.{a,la}
+}