media-sound/guitarix: bump to 0.44.0, dropped python3_7 from all

Bug: https://bugs.gentoo.org/839399
Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>

4 files changed, 94 insertions, 3 deletions

diff --git a/media-sound/guitarix/Manifest b/media-sound/guitarix/Manifest
index 06bc7470052d..1ffd14ca1ff4 100644
--- a/media-sound/guitarix/Manifest
+++ b/media-sound/guitarix/Manifest
@@ -1 +1,2 @@
 DIST guitarix2-0.43.1.tar.xz 71742288 BLAKE2B bfa72a20f5fe1bdd08162e283f7074f6bcd6b4d6ccb1771f0351e60802ebf030f8f6627d2480ccd2e5972215847edd62bff38c338723fd0bf2504b9b2cee5101 SHA512 30e56d863308cea18bb4af6f71d3e8d852662b4252c998507a1c3de9a2d97fe1c4ecb525bd35ef8e176b5cb5138806553cba157c1aa6cb14e48fe0bbea8a7def
+DIST guitarix2-0.44.0.tar.xz 71732636 BLAKE2B 1abc470ec7adc3286ee3edefc7652e95ec20d73c104cd20d9521c85d68ff4e91b70465ff05b7acc2c10b1902c976c6c93f171325494126f75707d5e3ea9affb8 SHA512 30520600ef60379770f40901a19219a044d442c77d0808df72957eb5f7fba7e6aef7ec2217735683033697144c3c9850963e89941d31ebb6b7490507a3e35f75
diff --git a/media-sound/guitarix/guitarix-0.43.1.ebuild b/media-sound/guitarix/guitarix-0.43.1.ebuild
index 32de3d3a96e1..cd2c72ecf68d 100644
--- a/media-sound/guitarix/guitarix-0.43.1.ebuild
+++ b/media-sound/guitarix/guitarix-0.43.1.ebuild
@@ -3,7 +3,7 @@
 
 EAPI=7
 
-PYTHON_COMPAT=( python3_{7..10} )
+PYTHON_COMPAT=( python3_{8..10} )
 PYTHON_REQ_USE='threads(+)'
 
 inherit python-any-r1 waf-utils xdg
diff --git a/media-sound/guitarix/guitarix-0.44.0.ebuild b/media-sound/guitarix/guitarix-0.44.0.ebuild
new file mode 100644
index 000000000000..d85e289e2d53
--- /dev/null
+++ b/media-sound/guitarix/guitarix-0.44.0.ebuild
@@ -0,0 +1,90 @@
+# Copyright 2019-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8..10} )
+PYTHON_REQ_USE='threads(+)'
+
+inherit python-any-r1 waf-utils xdg
+
+MY_P="${PN}2-${PV}"
+
+DESCRIPTION="Virtual guitar amplifier for Linux"
+HOMEPAGE="https://guitarix.org/"
+SRC_URI="mirror://sourceforge/guitarix/guitarix/${MY_P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="bluetooth debug lv2 nls nsm +standalone zeroconf"
+REQUIRED_USE="|| ( lv2 standalone )"
+
+DEPEND="
+	dev-cpp/eigen:3
+	dev-cpp/glibmm:2
+	dev-cpp/gtkmm:3.0
+	dev-libs/glib:2
+	media-libs/libsndfile
+	media-libs/zita-convolver:=
+	media-libs/zita-resampler
+	net-misc/curl
+	sci-libs/fftw:3.0=
+	x11-libs/gtk+:3
+	lv2? ( media-libs/lv2 )
+	standalone? (
+		dev-libs/boost:=
+		media-libs/liblrdf
+		media-libs/lilv
+		virtual/jack
+		bluetooth? ( net-wireless/bluez )
+		nsm? ( media-libs/liblo )
+		zeroconf? ( net-dns/avahi )
+	)
+"
+# roboto fonts are required for correct ui rendering
+RDEPEND="
+	${DEPEND}
+	standalone? (
+		media-fonts/roboto
+	)
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	virtual/pkgconfig
+	standalone? (
+		dev-lang/sassc
+		nls? (
+			dev-util/intltool
+			sys-devel/gettext
+		)
+	)
+"
+
+DOCS=( changelog README )
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.41.0-nostrip.patch
+)
+
+src_configure() {
+	local myconf=(
+		--cxxflags-debug=""
+		--cxxflags-release="-DNDEBUG"
+		--ldflags="${LDFLAGS}"
+		--enable-lfs
+		--lib-dev
+		--no-desktop-update
+		--no-faust
+		--no-ldconfig
+		--shared-lib
+		$(use_enable nls)
+		$(usex bluetooth "" "--no-bluez")
+		$(usex debug "--debug" "")
+		$(usex lv2 "--lv2dir=${EPREFIX}/usr/$(get_libdir)/lv2" "--no-lv2 --no-lv2-gui")
+		$(usex nsm "" "--no-nsm")
+		$(usex standalone "" "--no-standalone")
+		$(usex zeroconf "" "--no-avahi")
+	)
+	waf-utils_src_configure "${myconf[@]}"
+}
diff --git a/media-sound/guitarix/guitarix-9999.ebuild b/media-sound/guitarix/guitarix-9999.ebuild
index ac32a3ca36c9..7d35c3242486 100644
--- a/media-sound/guitarix/guitarix-9999.ebuild
+++ b/media-sound/guitarix/guitarix-9999.ebuild
@@ -1,9 +1,9 @@
-# Copyright 2019-2021 Gentoo Authors
+# Copyright 2019-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
 
-PYTHON_COMPAT=( python3_{7..10} )
+PYTHON_COMPAT=( python3_{8..10} )
 PYTHON_REQ_USE='threads(+)'
 
 inherit python-any-r1 waf-utils xdg git-r3