media-sound/ncmpcpp: add p20240724 & more

- improve visualzer message
- improve econf code
- update license for all files

Big thanks to mm1ke & juippis!

Signed-off-by: Filip Kobierski <fkobi@pm.me>
Closes: https://github.com/gentoo/gentoo/pull/37782
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

4 files changed, 77 insertions, 2 deletions

diff --git a/media-sound/ncmpcpp/Manifest b/media-sound/ncmpcpp/Manifest
index b4fa24e37a75..2052519ad8bf 100644
--- a/media-sound/ncmpcpp/Manifest
+++ b/media-sound/ncmpcpp/Manifest
@@ -1 +1,2 @@
 DIST ncmpcpp-0.9.2_p20221231.gh.tar.gz 229678 BLAKE2B edb03554a14b90fbb5a4c99cb46ed73ffd702ff2fa417765d4e4bdaddd6bc40554f18aae10db81af87bbc8c91a4f966785fefdf43cfc97b18fc950c1aa59a370 SHA512 8affb5115c7531ee005544f002068b0b13b6aa41c5e11213ba8c979373a5328f298612903e531b6d384749469d6fa0ddb0d06ac4dac5ab2ca5485c7814db32a3
+DIST ncmpcpp-0.9.2_p20240724.gh.tar.gz 230318 BLAKE2B dd1d464ab8a3e0d10b1a16c6737657190f57710c0e6d6da65270c8f10d1b8abe3877f9bc8b962df1ed82c5246576999f8f6e19523951657699b6b6670cc0e55d SHA512 9d7a52c6dde1459eb2a3606a43826007f43fcdcb01ddd9a1261ed427308dc909d5c73f1f01ffbaebc001b4b99c99ff0746aa869c6c31ae1fcabb70c3abc7f0ed
diff --git a/media-sound/ncmpcpp/ncmpcpp-0.9.2_p20221231.ebuild b/media-sound/ncmpcpp/ncmpcpp-0.9.2_p20221231.ebuild
index 90bf5a5ab81a..de3e7bbcf1d2 100644
--- a/media-sound/ncmpcpp/ncmpcpp-0.9.2_p20221231.ebuild
+++ b/media-sound/ncmpcpp/ncmpcpp-0.9.2_p20221231.ebuild
@@ -15,7 +15,7 @@ HOMEPAGE="
 SRC_URI="https://github.com/ncmpcpp/ncmpcpp/archive/${NCMPCPP_COMMIT}.tar.gz -> ${P}.gh.tar.gz"
 S="${WORKDIR}/${PN}-${NCMPCPP_COMMIT}"
 
-LICENSE="GPL-2"
+LICENSE="GPL-2+"
 SLOT="0"
 KEYWORDS="amd64 ~arm ~arm64 ~ppc ~ppc64 ~sparc x86"
 IUSE="clock outputs taglib visualizer"
diff --git a/media-sound/ncmpcpp/ncmpcpp-0.9.2_p20240724.ebuild b/media-sound/ncmpcpp/ncmpcpp-0.9.2_p20240724.ebuild
new file mode 100644
index 000000000000..7857b3212b84
--- /dev/null
+++ b/media-sound/ncmpcpp/ncmpcpp-0.9.2_p20240724.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+NCMPCPP_COMMIT="68daf44032784a5b5b74781a9bf3826053eff4a2"
+
+DESCRIPTION="Featureful ncurses based MPD client inspired by ncmpc"
+HOMEPAGE="
+	https://rybczak.net/ncmpcpp/
+	https://github.com/ncmpcpp/ncmpcpp/
+"
+SRC_URI="https://github.com/ncmpcpp/ncmpcpp/archive/${NCMPCPP_COMMIT}.tar.gz -> ${P}.gh.tar.gz"
+S="${WORKDIR}/${PN}-${NCMPCPP_COMMIT}"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="clock outputs taglib visualizer"
+
+RDEPEND="
+	>=media-libs/libmpdclient-2.1
+	dev-libs/boost:=[icu,nls]
+	dev-libs/icu:=
+	net-misc/curl
+	sys-libs/ncurses:=[unicode(+)]
+	sys-libs/readline:=
+	taglib? ( media-libs/taglib )
+	visualizer? ( sci-libs/fftw:3.0= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+src_prepare() {
+	default
+	eautoreconf
+
+	sed -i -e '/^docdir/d' {,doc/}Makefile{.am,.in} || die
+	sed -i -e 's|COPYING||g' Makefile{.am,.in} || die
+}
+
+src_configure() {
+	local myeconfargs=(
+		--without-lto # --with-lto only appends -flto. We need more for a dedicated USE flag
+		$(use_enable clock)
+		$(use_enable outputs)
+		$(use_enable visualizer)
+		$(use_with taglib)
+		$(use_with visualizer fftw)
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+
+	dodoc doc/{bindings,config}
+}
+
+pkg_postinst() {
+	echo
+	elog "Example configuration files have been installed at"
+	elog "${EROOT}/usr/share/doc/${PF}"
+	elog "${P} uses ~/.ncmpcpp/config and ~/.ncmpcpp/bindings"
+	elog "as user configuration files."
+	echo
+	if use visualizer; then
+		elog "If you want to use the visualizer, mpd needs to be built with fifo USE flag."
+		echo
+	fi
+}
diff --git a/media-sound/ncmpcpp/ncmpcpp-9999.ebuild b/media-sound/ncmpcpp/ncmpcpp-9999.ebuild
index 8c02f3f600fe..72c948365b60 100644
--- a/media-sound/ncmpcpp/ncmpcpp-9999.ebuild
+++ b/media-sound/ncmpcpp/ncmpcpp-9999.ebuild
@@ -12,7 +12,7 @@ HOMEPAGE="
 "
 EGIT_REPO_URI="https://github.com/ncmpcpp/ncmpcpp"
 
-LICENSE="GPL-2"
+LICENSE="GPL-2+"
 SLOT="0"
 IUSE="clock outputs taglib visualizer"