media-sound/gnome-music: bump to 3.36.7

Package-Manager: Portage-3.0.12, Repoman-3.0.2
Signed-off-by: Mart Raudsepp <leio@gentoo.org>

2 files changed, 82 insertions, 0 deletions

diff --git a/media-sound/gnome-music/Manifest b/media-sound/gnome-music/Manifest
index 2662d410f9e9..a7ebae569640 100644
--- a/media-sound/gnome-music/Manifest
+++ b/media-sound/gnome-music/Manifest
@@ -1 +1,2 @@
 DIST gnome-music-3.36.4.1.tar.xz 979064 BLAKE2B e744bee915a48a5d2366350cda7ebb0c43382f46de07d9203d95675cad45d825f2d93cc07be7865eceb5be3554ab478ecf84c52d9b8f5defc198b4f1b6638926 SHA512 8b6b4a8a44158a724de82855ba781dd6ceb53a30a35160f477721a385a841697f9a7c97cdba9a5bcc5b36834d55c034eb4c892907d550205dc5b7f7af56133ca
+DIST gnome-music-3.36.7.tar.xz 971980 BLAKE2B f27d0eb49a1728873ef6d439eead83cc34fb6802afdba3b4e0ef8d15c88d2012634ec0a18a4df4ba18079915d4227f526a93ac7989ce6ea4a807b620722fad1e SHA512 3470563621c17004d0b92451950ebfca203e830cb9ffe481fef7fe4d5187afa36ccb33130695226d4db95a89af9fac592910d2a19e715af4dd0c0ffba081c3a4
diff --git a/media-sound/gnome-music/gnome-music-3.36.7.ebuild b/media-sound/gnome-music/gnome-music-3.36.7.ebuild
new file mode 100644
index 000000000000..333450fc479b
--- /dev/null
+++ b/media-sound/gnome-music/gnome-music-3.36.7.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit gnome.org gnome2-utils meson python-single-r1 xdg
+
+DESCRIPTION="Music management for Gnome"
+HOMEPAGE="https://wiki.gnome.org/Apps/Music"
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE=""
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+DEPEND="${PYTHON_DEPS}
+	>=dev-libs/glib-2.50:2
+	>=net-libs/gnome-online-accounts-3.35.90[introspection]
+	>=dev-libs/gobject-introspection-1.54:=
+	>=x11-libs/gtk+-3.24.7:3[introspection]
+	>=dev-libs/libdazzle-3.28.0[introspection]
+	>=media-libs/libmediaart-1.9.1:2.0[introspection]
+	net-libs/libsoup:2.4[introspection]
+	>=app-misc/tracker-2.3.0:=[introspection(+)]
+	$(python_gen_cond_dep '
+		>=dev-python/pygobject-3.29.1:3[cairo,${PYTHON_MULTI_USEDEP}]
+		>=dev-python/pycairo-1.14.0[${PYTHON_MULTI_USEDEP}]
+	')
+	>=media-libs/grilo-0.3.12:0.3[introspection]
+	>=media-plugins/grilo-plugins-0.3.10:0.3
+"
+# xdg-user-dirs-update needs to be there to create needed dirs
+# https://bugzilla.gnome.org/show_bug.cgi?id=731613
+RDEPEND="${DEPEND}
+	|| (
+		>=app-misc/tracker-miners-2.2.0[gstreamer]
+		>=app-misc/tracker-miners-2.2.0[ffmpeg]
+	)
+	x11-libs/libnotify[introspection]
+	media-libs/gstreamer:1.0[introspection]
+	media-libs/gst-plugins-base:1.0[introspection]
+	media-plugins/gst-plugins-meta:1.0
+	media-plugins/grilo-plugins:0.3[tracker]
+	x11-misc/xdg-user-dirs
+"
+BDEPEND="
+	dev-libs/libxml2:2
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+RESTRICT="test" # only does desktop and appdata validation, and latter needs network to validate screenshot from https
+
+pkg_setup() {
+	python_setup
+}
+
+src_prepare() {
+	sed -e '/sys.path.insert/d' -i "${S}"/gnome-music.in || die "python fixup sed failed"
+	xdg_src_prepare
+}
+
+src_install() {
+	meson_src_install
+	python_fix_shebang "${D}"/usr/bin/gnome-music
+	python_optimize
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}