media-sound/deadbeef: drop 1.9.6_beta2

Signed-off-by: Viorel Munteanu <ceamac@gentoo.org>

2 files changed, 0 insertions, 206 deletions

diff --git a/media-sound/deadbeef/Manifest b/media-sound/deadbeef/Manifest
index 27eb592754ef..d5cd45eb2c29 100644
--- a/media-sound/deadbeef/Manifest
+++ b/media-sound/deadbeef/Manifest
@@ -1,3 +1,2 @@
 DIST deadbeef-1.9.5.tar.bz2 5204015 BLAKE2B 45b9023807a5652c38f6cafd5ea0fca87e2872db264538f5c9d9ee4815281fe3f4e08eee5d43a083a67b3a9f646de24a90147d76f15622710d8f4adbdabe0c8d SHA512 c7a15f47fd8081a363e5cba732aa4ff4b1c311408728fbc5f7f47cf349bc112274a1d9fe0df8a58f09abf8f7656d914fb1baafa38fdf4dcb38fae7e1f70f682c
-DIST deadbeef-1.9.6_beta2.tar.bz2 5194057 BLAKE2B 1b1904176fa0ad0ac32cf87d0558eaa865707ccad8c75b8520bbab5c70aefeaeeb8f65c894f2516a10832caa5729db50fc0405b09aed89709d749294b065de7a SHA512 c62f21f23c71ad83e8f073979c57e68b2814252833cf051ff899d07f4ac41b3d52a83327b8efa97fb2c5a0be1856d2513b22c8b209135c7f6d793a219a7461b9
 DIST deadbeef-1.9.6_rc1.tar.bz2 5193940 BLAKE2B ad6ce7297e40f317bb2615485161e9dc051e2f4d1add905da56f391231947e6e113259c21e01aed64ab710b20c09b116104d7acee778f86dda7a9b37501f616d SHA512 a35a35a0d49ede2514f5047ee936712863ee6df1f0aabba037ccc7b84c4f58e12d9729fd3e2268abad65c04fb1fa4ac625e41093e3e812dbced1ce3869012aeb
diff --git a/media-sound/deadbeef/deadbeef-1.9.6_beta2.ebuild b/media-sound/deadbeef/deadbeef-1.9.6_beta2.ebuild
deleted file mode 100644
index 1386b82f85f1..000000000000
--- a/media-sound/deadbeef/deadbeef-1.9.6_beta2.ebuild
+++ /dev/null
@@ -1,205 +0,0 @@
-# Copyright 2021-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit autotools xdg flag-o-matic toolchain-funcs plocale
-
-MY_PV=${PV/_/-}
-DL_PV=$(ver_cut 1-2)
-
-DESCRIPTION="DeaDBeeF is a modular audio player similar to foobar2000"
-HOMEPAGE="https://deadbeef.sourceforge.io/"
-SRC_URI="https://sourceforge.net/projects/${PN}/files/travis/linux/${DL_PV}/deadbeef-${MY_PV}.tar.bz2/download
-	-> ${P}.tar.bz2"
-S="${WORKDIR}"/${PN}-${MY_PV}
-
-LICENSE="
-	GPL-2
-	LGPL-2.1
-	wavpack? ( BSD )
-"
-SLOT="0"
-IUSE="aac alsa cdda converter cover dts ffmpeg flac +hotkeys lastfm libretro libsamplerate mp3 musepack nls notify +nullout opus oss pulseaudio pipewire sc68 shellexec +supereq vorbis wavpack"
-
-REQUIRED_USE="
-	|| ( alsa oss pulseaudio pipewire nullout )
-"
-
-DEPEND="
-	>=app-accessibility/at-spi2-core-2.46.0
-	dev-libs/glib:2
-	dev-libs/jansson:=
-	dev-libs/libdispatch
-	net-misc/curl
-	x11-libs/cairo
-	x11-libs/gdk-pixbuf:2
-	x11-libs/gtk+:3
-	x11-libs/libX11
-	x11-libs/pango
-	aac? ( media-libs/faad2 )
-	alsa? ( media-libs/alsa-lib )
-	cdda? (
-		dev-libs/libcdio:=
-		media-libs/libcddb
-		media-sound/cdparanoia
-	)
-	cover? ( media-libs/imlib2[jpeg,png] )
-	dts? ( media-libs/libdca )
-	ffmpeg? ( media-video/ffmpeg:= )
-	flac? (
-		media-libs/flac:=
-		media-libs/libogg
-	)
-	libsamplerate? ( media-libs/libsamplerate )
-	mp3? ( media-sound/mpg123 )
-	musepack? ( media-sound/musepack-tools )
-	nls? ( virtual/libintl )
-	notify? ( sys-apps/dbus )
-	opus? ( media-libs/opusfile )
-	pulseaudio? ( media-libs/libpulse )
-	pipewire? ( media-video/pipewire:= )
-	vorbis? ( media-libs/libvorbis )
-	wavpack? ( media-sound/wavpack )
-"
-
-RDEPEND="${DEPEND}"
-BDEPEND="
-	dev-util/intltool
-	sys-devel/clang
-	>=sys-devel/gettext-0.21
-	sys-devel/llvm
-	virtual/pkgconfig
-"
-
-PATCHES=(
-	"${FILESDIR}"/${PN}-1.9.6-drop-Werror.patch
-	"${FILESDIR}"/${PN}-1.9.6-update-gettext.patch
-	"${FILESDIR}"/${PN}-1.9.6-fix-desktop-launcher.patch
-)
-
-src_prepare() {
-	default
-
-	drop_from_linguas() {
-		sed "/${1}/d" -i "${S}/po/LINGUAS" || die
-	}
-
-	drop_and_stub() {
-		einfo drop_and_stub "${1}"
-		rm -r "${1}" || die
-		mkdir "${1}" || die
-		cat > "${1}/Makefile.in" <<-EOF || die
-			all: nothing
-			install: nothing
-			nothing:
-		EOF
-	}
-
-	plocale_for_each_disabled_locale drop_from_linguas || die
-
-	eautopoint --force
-	eautoreconf
-
-	# Get rid of bundled gettext. (Avoid build failures with musl)
-	drop_and_stub "${S}/intl"
-
-	# Plugins that are undesired for whatever reason, candidates for unbundling and such.
-	for i in adplug alac dumb ffap mms gme mono2stereo psf shn sid soundtouch wma; do
-		drop_and_stub "${S}/plugins/${i}"
-	done
-
-	rm -r "${S}/plugins/rg_scanner/ebur128" || die
-}
-
-src_configure () {
-	if ! tc-is-clang; then
-		AR=llvm-ar
-		CC=${CHOST}-clang
-		CXX=${CHOST}-clang++
-		NM=llvm-nm
-		RANLIB=llvm-ranlib
-
-		strip-unsupported-flags
-	fi
-
-	export HOST_CC="$(tc-getBUILD_CC)"
-	export HOST_CXX="$(tc-getBUILD_CXX)"
-	tc-export CC CXX LD AR NM OBJDUMP RANLIB PKG_CONFIG
-
-	local myconf=(
-		"--disable-staticlink"
-		"--disable-portable"
-		"--disable-rpath"
-
-		"--disable-libmad"
-		"--disable-gtk2"
-		"--disable-adplug"
-		"--disable-coreaudio"
-		"--disable-dumb"
-		"--disable-alac"
-		"--disable-ffap"
-		"--disable-gme"
-		"--disable-mms"
-		"--disable-mono2stereo"
-		"--disable-psf"
-		"--disable-rgscanner"
-		"--disable-shn"
-		"--disable-sid"
-		"--disable-sndfile"
-		"--disable-soundtouch"
-		"--disable-tta"
-		"--disable-vfs-zip"
-		"--disable-vtx"
-		"--disable-wildmidi"
-		"--disable-wma"
-
-		"$(use_enable alsa)"
-		"$(use_enable oss)"
-		"$(use_enable pulseaudio pulse)"
-		"$(use_enable mp3)"
-		"$(use_enable mp3 libmpg123)"
-		"$(use_enable nls)"
-		"$(use_enable vorbis)"
-		"$(use_enable flac)"
-		"$(use_enable supereq)"
-		"$(use_enable cdda)"
-		"$(use_enable cdda cdda-paranoia)"
-		"$(use_enable aac)"
-		"$(use_enable cover artwork)"
-		"$(use_enable cover artwork-network)"
-		"$(use_enable dts dca)"
-		"$(use_enable ffmpeg)"
-		"$(use_enable converter)"
-		"$(use_enable musepack)"
-		"$(use_enable notify)"
-		"$(use_enable nullout)"
-		"$(use_enable opus)"
-		"$(use_enable pulseaudio pulse)"
-		"$(use_enable pipewire)"
-		"$(use_enable sc68)"
-		"$(use_enable shellexec)"
-		"$(use_enable shellexec shellexecui)"
-		"$(use_enable lastfm lfm)"
-		"$(use_enable libretro)"
-		"$(use_enable libsamplerate src)"
-		"$(use_enable wavpack)"
-
-		"--enable-gtk3"
-		"--enable-vfs-curl"
-		"--enable-shared"
-		"--enable-m3u"
-		"--enable-pltbrowser"
-	)
-
-	econf "${myconf[@]}"
-}
-
-src_install() {
-	default
-
-	find "${ED}" -name '*.la' -delete || die
-
-	# if compressed, help doesn't work
-	docompress -x /usr/share/doc/${PF}
-}