media-sound/ncmpc: bump to 0.50

Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>

2 files changed, 70 insertions, 0 deletions

diff --git a/media-sound/ncmpc/Manifest b/media-sound/ncmpc/Manifest
index 3c2aa611ee2b..c26c77676e8f 100644
--- a/media-sound/ncmpc/Manifest
+++ b/media-sound/ncmpc/Manifest
@@ -1 +1,2 @@
 DIST ncmpc-0.49.tar.xz 296012 BLAKE2B c87c07bcf107e20224982a99fdedb09468ed510f7e6138e6e35386c636bdf62a3fd79e609670f7931966e3be09de668d1119ade950f2b8e4cd7c546d47a405be SHA512 9913f08d90b229af59c8da0ac737445661dc69f0174f996dedbd0c9d9c4833004dbd9319f6bc08dc8b35a191ae167c090a3f31b43167e1918c5fad8f044a4c17
+DIST ncmpc-0.50.tar.xz 312508 BLAKE2B 5e1d2a52a9cfee9ba92e1ea390a3ff80ed26be662e1a12bee1f1a6e84a10043f5a546bd2d09a38753b244427fcc415f30de4fe369fb19fe45681f9d81b7e9844 SHA512 c59351e553169a4ebf6b7086083838fd1295eb2fcc5d352e622a086a487b8cb7b36e565dbbe02e7924233ef530ce4b74fab79e5dfaa4ad4b57bf472eb74fc839
diff --git a/media-sound/ncmpc/ncmpc-0.50.ebuild b/media-sound/ncmpc/ncmpc-0.50.ebuild
new file mode 100644
index 000000000000..85aebc139068
--- /dev/null
+++ b/media-sound/ncmpc/ncmpc-0.50.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson
+
+DESCRIPTION="Ncurses client for the Music Player Daemon (MPD)"
+HOMEPAGE="https://www.musicpd.org/clients/ncmpc/ https://github.com/MusicPlayerDaemon/ncmpc"
+SRC_URI="https://www.musicpd.org/download/${PN}/${PV%.*}/${P}.tar.xz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="async-connect chat-screen doc +help-screen key-screen +library-screen lirc lyrics-screen +mouse nls outputs-screen pcre search-screen +song-screen test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	virtual/pkgconfig
+	doc? ( dev-python/sphinx )
+"
+RDEPEND="
+	media-libs/libmpdclient
+	sys-libs/ncurses:=[unicode(+)]
+	lirc? ( app-misc/lirc )
+	pcre? ( dev-libs/libpcre2 )
+"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	default
+
+	# use correct docdir and don't install license file
+	sed -e "/^docdir =/s/meson.project_name()/'${PF}'/" \
+		-e "s/'COPYING', //" \
+		-i meson.build || die
+
+	# use correct (html) docdir
+	sed -e "/install_dir:.*doc/s/meson.project_name()/'${PF}'/" \
+		-i doc/meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dcurses=ncursesw
+		-Dcolors=true
+		-Dmini=false
+		-Dlyrics_plugin_dir="${EPREFIX}/usr/$(get_libdir)/ncmpc/lyrics"
+		-Dasync_connect=$(usex async-connect true false)
+		-Dchat_screen=$(usex chat-screen true false)
+		-Ddocumentation=$(usex doc enabled disabled)
+		-Dhelp_screen=$(usex help-screen true false)
+		-Dkey_screen=$(usex key-screen true false)
+		-Dlibrary_screen=$(usex library-screen true false)
+		-Dlirc=$(usex lirc enabled disabled)
+		-Dlocale=$(usex nls enabled disabled)
+		-Dlyrics_screen=$(usex lyrics-screen true false)
+		-Dmouse=$(usex mouse enabled disabled)
+		-Dmultibyte=$(usex nls true false)
+		-Dnls=$(usex nls enabled disabled)
+		-Doutputs_screen=$(usex outputs-screen true false)
+		-Dregex=$(usex pcre enabled disabled)
+		-Dsearch_screen=$(usex search-screen true false)
+		-Dsong_screen=$(usex song-screen true false)
+		$(meson_use test)
+	)
+
+	meson_src_configure
+}