media-video/libva-utils: fixed dependencies, minor other fixes

1. While it is declared that libva-utils are backward compatible with
the older version of libva, it is not truth. Let's require similar
version of libva as dependency. Bug: https://bugs.gentoo.org/743835
2. Xext, Xfixes and libdrm are not required anymore starting from
version 2.7.1 of libva-utils. Dropped.
3. Sometimes the upstream publishes tarballs with generated
'configure'. Let's use it.

Closes: https://bugs.gentoo.org/743835
Signed-off-by: Karlson2k (Evgeny Grin) <k2k@narod.ru>
Closes: https://github.com/gentoo/gentoo/pull/18943
Signed-off-by: Sam James <sam@gentoo.org>

1 files changed, 75 insertions, 0 deletions

diff --git a/media-video/libva-utils/libva-utils-2.8.0-r1.ebuild b/media-video/libva-utils/libva-utils-2.8.0-r1.ebuild
new file mode 100644
index 000000000000..9c75a569bdb2
--- /dev/null
+++ b/media-video/libva-utils/libva-utils-2.8.0-r1.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+if [[ ${PV} = *9999* ]] ; then # Live ebuild
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/intel/libva-utils"
+fi
+
+if [[ ${PV} = 2.8.0 ]]; then
+	AUTOCONFIGURED="true"
+else
+	AUTOCONFIGURED="false"
+fi
+
+if ! ${AUTOCONFIGURED}; then
+	inherit autotools
+fi
+
+DESCRIPTION="Collection of utilities and tests for VA-API"
+HOMEPAGE="https://01.org/linuxmedia/vaapi"
+if [[ ${PV} != *9999* ]] ; then
+	if ${AUTOCONFIGURED}; then
+		SRC_URI="https://github.com/intel/libva-utils/releases/download/${PV}/${P}.tar.bz2"
+	else
+		SRC_URI="https://github.com/intel/libva-utils/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	fi
+	KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86 ~amd64-linux ~x86-linux"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="+drm test wayland X"
+RESTRICT="!test? ( test )"
+
+REQUIRED_USE="|| ( drm wayland X )"
+
+BDEPEND="
+	virtual/pkgconfig
+"
+DEPEND="
+	>=x11-libs/libva-${PV}:=[drm?,wayland?,X?]
+	wayland? ( >=dev-libs/wayland-1.0.6 )
+	X? ( >=x11-libs/libX11-1.6.2 )
+"
+RDEPEND="${DEPEND}"
+
+DOCS=( NEWS )
+
+src_prepare() {
+	default
+	sed -e 's/-Werror//' -i test/Makefile.am || die
+	if ${AUTOCONFIGURED}; then
+		sed -e 's/-Werror//' -i test/Makefile.in || die
+		touch ./configure || die
+	else
+		eautoreconf
+	fi
+}
+
+src_configure() {
+	local myeconfargs=(
+		$(use_enable drm)
+		$(use_enable test tests)
+		$(use_enable wayland)
+		$(use_enable X x11)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	[[ ${PV} = *9999* ]] && DOCS+=( CONTRIBUTING.md README.md )
+	default
+}