media-video/qmplay2: add 24.12.23

Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>

2 files changed, 139 insertions, 0 deletions

diff --git a/media-video/qmplay2/Manifest b/media-video/qmplay2/Manifest
index 0a91513791b3..f7749f5790a2 100644
--- a/media-video/qmplay2/Manifest
+++ b/media-video/qmplay2/Manifest
@@ -1,2 +1,3 @@
 DIST QMPlay2-src-24.06.16.tar.xz 2042180 BLAKE2B ba076fc7cb6c77f16529d082690c4d994e53c62cdf994c1e35afdb5255b203d0ccc72db1195730be60471d5fff48deca47e1348b0b41f22e898818206f8c53bb SHA512 3a8a7b99c7861318cfe0a6e096a27bb86f64cfafacf4ec52bdc4e955dd320d6e0f369dcb466dfd9bb73f8d173a2fc768848e7356f03590e429ae30270daf176b
 DIST QMPlay2-src-24.12.06.tar.xz 2058012 BLAKE2B adc53f14c9614114b6c401a757278faa76d6e9ad467ab12c994e69d078aa181e4c956c07dac545a0aa91cf2258e82f16710b257ddf3f39b64655d44ef4649952 SHA512 fbfbd477ff44e9b74f1892788d0d13edd26df394fd91956a1db1d5355197c8f4662f844a3279a3efc07f38289c7394507e2cbc3c74c162eb7514badcba6ca331
+DIST QMPlay2-src-24.12.23.tar.xz 2065360 BLAKE2B d1f015246ad1a38645009bd7f41ec48236f0d7ed0a1cce3ef7960245af44b317890cba6a06018c018d2181c0a93e61155cf9a267cfe3750949a8c19c5fd9b959 SHA512 c7d563e3c35ea4fffa4878a5747b6e648601fb5281d129f57f3fc8784aba938025cd160763963ee1eeecda2e336a358738255bbe560b58cc609fb122b2531e81
diff --git a/media-video/qmplay2/qmplay2-24.12.23.ebuild b/media-video/qmplay2/qmplay2-24.12.23.ebuild
new file mode 100644
index 000000000000..1bb22871659a
--- /dev/null
+++ b/media-video/qmplay2/qmplay2-24.12.23.ebuild
@@ -0,0 +1,138 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake xdg
+
+DESCRIPTION="A Qt-based video player, which can play most formats and codecs"
+HOMEPAGE="https://github.com/zaps166/QMPlay2"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/zaps166/QMPlay2"
+else
+	SRC_URI="https://github.com/zaps166/QMPlay2/releases/download/${PV}/QMPlay2-src-${PV}.tar.xz"
+	S="${WORKDIR}/QMPlay2-src-${PV}"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="LGPL-3"
+SLOT="0"
+
+IUSE="avdevice +audiofilters +alsa cdio cuvid extensions gme inputs libass
+	modplug notifications opengl pipewire portaudio pulseaudio qt6 sid
+	shaders +taglib vaapi videofilters visualizations vulkan xv"
+
+REQUIRED_USE="
+	audiofilters? ( || ( alsa pipewire portaudio pulseaudio ) )
+	shaders? ( vulkan )
+"
+
+RDEPEND="
+	media-video/ffmpeg:=[vaapi?]
+	!qt6? (
+		dev-qt/qtcore:5
+		dev-qt/qtdbus:5
+		dev-qt/qtgui:5[X(-),vulkan?]
+		dev-qt/qtsvg:5
+		dev-qt/qtwidgets:5
+		dev-qt/qtx11extras:5
+		extensions? ( dev-qt/qtdeclarative:5 )
+		videofilters? ( dev-qt/qtconcurrent:5 )
+	)
+	qt6? (
+		dev-qt/qtbase:6[concurrent,dbus,gui,network,opengl?,ssl,vulkan?,widgets]
+		dev-qt/qt5compat:6
+		dev-qt/qtsvg:6
+		extensions? ( dev-qt/qtdeclarative:6 )
+	)
+	alsa? ( media-libs/alsa-lib )
+	cdio? ( dev-libs/libcdio[cddb] )
+	gme? ( media-libs/game-music-emu )
+	libass? ( media-libs/libass )
+	opengl? ( virtual/opengl )
+	pipewire? ( media-video/pipewire )
+	portaudio? ( media-libs/portaudio )
+	pulseaudio? ( media-libs/libpulse )
+	sid? ( media-libs/libsidplayfp )
+	shaders? ( >=media-libs/shaderc-2020.1 )
+	taglib? ( media-libs/taglib	)
+	vaapi? ( media-libs/libva[X] )
+	vulkan? ( >=media-libs/vulkan-loader-1.2.133 )
+	xv? ( x11-libs/libXv )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	!qt6? ( dev-qt/linguist-tools:5 )
+	qt6? ( dev-qt/qttools:6[linguist] )
+"
+
+src_prepare() {
+	# disable compress man pages
+	sed -r \
+		-e 's/if\(GZIP\)/if\(TRUE\)/' \
+		-e 's/(install.+QMPlay2\.1)\.gz/\1/' \
+		-i src/gui/CMakeLists.txt || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_WITH_QT6=$(usex qt6)
+		# core
+		-DUSE_UPDATES=OFF
+		-DUSE_ALSA=$(usex alsa)
+		-DUSE_AUDIOCD=$(usex cdio)
+		-DUSE_DBUS_PM=ON
+		-DUSE_FREEDESKTOP_NOTIFICATIONS=ON
+		-DUSE_LIBASS=$(usex libass)
+		-DUSE_NOTIFY=$(usex notifications)
+		-DUSE_OPENGL=$(usex opengl)
+		-DUSE_VULKAN=$(usex vulkan)
+		-DUSE_GLSLC=$(usex shaders)
+		-DUSE_XVIDEO=$(usex xv)
+
+		# ffmpeg
+		-DUSE_FFMPEG_AVDEVICE=$(usex avdevice)
+		-DUSE_FFMPEG_VAAPI=$(usex vaapi)
+
+		# chiptune
+		-DUSE_CHIPTUNE_GME=$(usex gme)
+		-DUSE_CHIPTUNE_SID=$(usex sid)
+
+		# modules
+		-DUSE_AUDIOFILTERS=$(usex audiofilters)
+		-DUSE_CUVID=$(usex cuvid)
+		-DUSE_INPUTS=$(usex inputs)
+		-DUSE_MODPLUG=$(usex modplug)
+		-DUSE_PIPEWIRE=$(usex pipewire)
+		-DUSE_PORTAUDIO=$(usex portaudio)
+		-DUSE_PULSEAUDIO=$(usex pulseaudio)
+		-DUSE_TAGLIB=$(usex taglib)
+		-DUSE_VIDEOFILTERS=$(usex videofilters)
+		-DUSE_VISUALIZATIONS=$(usex visualizations)
+
+		# extensions
+		-DUSE_EXTENSIONS=$(usex extensions)
+	)
+
+	if use extensions; then
+		# Move inside an if, to remove unused option warning
+		mycmakeargs+=(
+			-DUSE_LASTFM=ON
+			-DUSE_LYRICS=ON
+			-DUSE_MEDIABROWSER=ON
+			-DUSE_MPRIS2=ON
+		)
+	fi
+
+	if [[ ${PV} == *9999 ]]; then
+		mycmakeargs+=( -DUSE_GIT_VERSION=true )
+	else
+		mycmakeargs+=( -DUSE_GIT_VERSION=false )
+	fi
+
+	cmake_src_configure
+}