net-im/mattermost-desktop-bin: add 5.5.1_rc1

Signed-off-by: Viorel Munteanu <ceamac@gentoo.org>

2 files changed, 95 insertions, 0 deletions

diff --git a/net-im/mattermost-desktop-bin/Manifest b/net-im/mattermost-desktop-bin/Manifest
index 411a46aaa33c..c0c597388994 100644
--- a/net-im/mattermost-desktop-bin/Manifest
+++ b/net-im/mattermost-desktop-bin/Manifest
@@ -1,2 +1,4 @@
 DIST mattermost-desktop-5.5.0-linux-arm64.tar.gz 100549584 BLAKE2B fd66d80c2086c6d27988de8673f430fefe1c77673e92cde34aff42249b1188f83d90d63120d2bed9f138190f61bfa3ab143c80dc93388af0f36818cbc03abed4 SHA512 91975d410a2de844367be43eeb0fc5d030b528792e519e3315a571341753e3b06107fc2f7ecf42bb553137fc869f40a28adbb938894b2f73a4ddd82314b12b9f
 DIST mattermost-desktop-5.5.0-linux-x64.tar.gz 99975458 BLAKE2B 7cf6080425446bc9359e754cb74cd16f21fdb79ef71741b05d3adb2a480da42db16437211d5c523380524faface12e0d211af15bfa3aab57edaebc53eccdc73f SHA512 ecd6338e8ceffae98087af0e882f0c69aa45e3b24990f015580ba15ef246862521965084bde18b35030c1e172f7d5f21d7690fab3439b1d470f56942e9616efe
+DIST mattermost-desktop-5.5.1-rc.1-linux-arm64.tar.gz 100453908 BLAKE2B d80e48c75a50b026801700b0cefa729879f13092d859965d190baa20632937b2e2d9f0a6a9d0b36c847151a280bf037f89c4ca58d9c54fca752dcb56c0740027 SHA512 2bad418f80217b3524b2476f147003ccd511b8eabf8d12e9e0a58f1b8df8b004e329d554ec4c7def35a7c36a1fa5395735e3f885ba7595c54367fb74d48dd4bc
+DIST mattermost-desktop-5.5.1-rc.1-linux-x64.tar.gz 99897869 BLAKE2B ed183c44d9c24a1635e3c4ffacbbfa63434f1d374ee659a75976564cbae8863c54e9cc801b6688d427990fe9706d2c056e72caf02cbcc8144e0dd2cf8721cb62 SHA512 102f52fd3b97be05c46afe65e582ba756a07dd0d320d14df49a3280e8c06a0b6062033f8dddcb4db9b2b6e5705da67f30020dc39fec32eec5b9017e00dd38cff
diff --git a/net-im/mattermost-desktop-bin/mattermost-desktop-bin-5.5.1_rc1.ebuild b/net-im/mattermost-desktop-bin/mattermost-desktop-bin-5.5.1_rc1.ebuild
new file mode 100644
index 000000000000..339810206271
--- /dev/null
+++ b/net-im/mattermost-desktop-bin/mattermost-desktop-bin-5.5.1_rc1.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_PN="${PN%-*}"
+MY_PV="${PV/_rc/-rc.}"
+
+inherit desktop xdg
+
+DESCRIPTION="Mattermost Desktop application"
+HOMEPAGE="https://mattermost.com/"
+
+SRC_URI="
+	amd64? ( https://releases.mattermost.com/desktop/${MY_PV}/mattermost-desktop-${MY_PV}-linux-x64.tar.gz )
+	arm64? ( https://releases.mattermost.com/desktop/${MY_PV}/mattermost-desktop-${MY_PV}-linux-arm64.tar.gz )
+"
+S="${WORKDIR}"
+
+LICENSE="Apache-2.0 GPL-2+ LGPL-2.1+ MIT"
+SLOT="0"
+# Starting with 5.2.0 upstream dropped x86 for their binary release #879519
+if [[ ${PV} != *rc* ]]; then
+	KEYWORDS="~amd64 ~arm64"
+fi
+
+RDEPEND="
+	>=app-accessibility/at-spi2-core-2.46.0:2[X]
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	dev-libs/wayland
+	media-libs/alsa-lib
+	media-libs/mesa
+	net-print/cups
+	sys-apps/dbus
+	sys-libs/glibc
+	x11-libs/cairo
+	x11-libs/gtk+:3[X]
+	x11-libs/libX11
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXrandr
+	x11-libs/libdrm
+	x11-libs/libxcb
+	x11-libs/libxkbcommon
+	x11-libs/pango
+"
+
+QA_PREBUILT="
+	opt/mattermost-desktop/mattermost-desktop
+	opt/mattermost-desktop/libnode.so
+	opt/mattermost-desktop/libffmpeg.so
+	opt/mattermost-desktop/libGLESv2.so
+	opt/mattermost-desktop/libEGL.so
+	opt/mattermost-desktop/libvk_swiftshader.so
+	opt/mattermost-desktop/libvulkan.so.1
+	opt/mattermost-desktop/resources/*
+"
+
+DOCS=(
+	NOTICE.txt
+)
+
+src_install() {
+	if use amd64; then
+		cd mattermost-desktop-${MY_PV}-linux-x64 || die
+	elif use arm64; then
+		cd mattermost-desktop-${MY_PV}-linux-arm64 || die
+	fi
+	newicon app_icon.png ${MY_PN}.png
+
+	insinto "/opt/${MY_PN}/locales"
+	doins locales/*.pak
+
+	insinto "/opt/${MY_PN}/resources"
+	doins -r resources/*.asar*
+
+	insinto "/opt/${MY_PN}"
+	doins *.pak *.bin *.dat
+	exeinto "/opt/${MY_PN}"
+	doexe *.so *.so.* "${MY_PN}"
+
+	dosym -r "/opt/${MY_PN}/${MY_PN}" "/usr/bin/${MY_PN}"
+
+	make_desktop_entry "${MY_PN} --enable-features=WaylandWindowDecorations --ozone-platform-hint=auto" \
+		Mattermost "${MY_PN}"
+
+	einstalldocs
+}