net-irc/ngircd: bump to version 24

- Updated copyright years
- Updated ebuild to EAPI6
- Cleaned up USE=ssl
- Added USE=test and dependencies to prepare for unrestricting
  FEATURES=test (one testcase is currently failing)

Signed-off-by: Moritz Kick <gentoo@blackphoenix.de>

1 files changed, 93 insertions, 0 deletions

diff --git a/net-irc/ngircd/ngircd-24.ebuild b/net-irc/ngircd/ngircd-24.ebuild
new file mode 100644
index 000000000000..43f11068ec8c
--- /dev/null
+++ b/net-irc/ngircd/ngircd-24.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="6"
+
+inherit user
+
+DESCRIPTION="An IRC server written from scratch"
+HOMEPAGE="https://ngircd.barton.de/"
+SRC_URI="https://arthur.barton.de/pub/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~x64-macos"
+IUSE="debug gnutls iconv ident ipv6 libressl pam ssl tcpd test zlib"
+
+RDEPEND="
+	iconv? ( virtual/libiconv )
+	ident? ( net-libs/libident )
+	pam? ( virtual/pam )
+	ssl? (
+		gnutls? ( net-libs/gnutls:= )
+		!gnutls? (
+			!libressl? ( dev-libs/openssl:0= )
+			libressl? ( dev-libs/libressl:0= )
+		)
+	)
+	tcpd? ( sys-apps/tcp-wrappers )
+	zlib? ( sys-libs/zlib )
+"
+
+DEPEND="${RDEPEND}
+	>=sys-apps/sed-4
+	test? (
+		dev-tcltk/expect
+		net-misc/netkit-telnetd
+	)
+"
+
+# Testsuite fails server-login-test
+RESTRICT="test"
+
+src_prepare() {
+	default
+
+	if ! use prefix; then
+		sed -i \
+			-e "s:;ServerUID = 65534:ServerUID = ngircd:" \
+			-e "s:;ServerGID = 65534:ServerGID = nogroup:" \
+			doc/sample-ngircd.conf.tmpl || die
+	fi
+}
+
+src_configure() {
+	local myconf=(
+		--sysconfdir="${EPREFIX}"/etc/"${PN}"
+		$(use_enable debug sniffer)
+		$(use_enable debug)
+		$(use_enable ipv6)
+		$(use_with iconv)
+		$(use_with ident)
+		$(use_with pam)
+		$(use_with tcpd tcp-wrappers)
+		$(use_with zlib)
+	)
+
+	if use ssl; then
+		myconf+=(
+			$(use_with !gnutls openssl)
+			$(use_with gnutls)
+		)
+	else
+		myconf+=(
+			--without-gnutls
+			--without-openssl
+		)
+	fi
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+	newinitd "${FILESDIR}"/ngircd.init-r1.d ngircd
+}
+
+pkg_postinst() {
+	if ! use prefix; then
+		enewuser ngircd
+		chown ngircd "${EROOT%/}"/etc/ngircd/ngircd.conf || die
+	fi
+}