net-irc/limnoria: bump to 2021-05-27

Package-Manager: Portage-3.0.19, Repoman-3.0.3
Signed-off-by: Sam Jorna <wraeth@gentoo.org>

2 files changed, 79 insertions, 0 deletions

diff --git a/net-irc/limnoria/Manifest b/net-irc/limnoria/Manifest
index ea8536ba4213..fbf47f600f3c 100644
--- a/net-irc/limnoria/Manifest
+++ b/net-irc/limnoria/Manifest
@@ -1,2 +1,3 @@
 DIST limnoria-20210326.tar.gz 1046488 BLAKE2B fcbaab1ecebcd74438be4c2fce96c7e289aa01dcb67c324130d5c768727e159c87b5d96cc4ffefdf629287d59f02cc72ea17ba4a61e9157d7626ebceb9e072e8 SHA512 1d612a2ce42edec909255474f99b4785ff7eb7a7554ee5090e05db92cadb071821f6962659d8f1846f238a257d6b8d513881f27be44a7582d154bd0cf398f7db
 DIST limnoria-20210411.tar.gz 1084991 BLAKE2B 6bca9a2583748ae2b1c26670a762d0ee1307478b6d587e32c816c880d4d1ac6495f79d07bd8d7068867b1a9dd1bff51233e5636c0d0371e2ee1c19617a9a7872 SHA512 2c53d6ecd2457fae77076ad5ee0c4fa61c42970f8d43891b6d9adbabae80176ccab2789fc6a7129db3545a76f1850cf86de50aa3814b335d42f1220a2818c36c
+DIST limnoria-20210527.tar.gz 1092017 BLAKE2B 1c01ecbb47927d62e30e1768bb8e4574bad7422fea379ddd3d6700351a2f8dd006370a24aeeb7a5b10003e53f1010c8fb3998ecf1ef4f11a2ce48f9145605d30 SHA512 2e09415931cb3bdc358d4a243be3f1abccd569f2371d5d2b2c67e856492475affa473c8c32c77cb2c973b64202f9c6657397fa35b5b16086fbaf4e5b44706184
diff --git a/net-irc/limnoria/limnoria-20210527.ebuild b/net-irc/limnoria/limnoria-20210527.ebuild
new file mode 100644
index 000000000000..03b9171f694b
--- /dev/null
+++ b/net-irc/limnoria/limnoria-20210527.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+DISTUTILS_USE_SETUPTOOLS=no
+inherit distutils-r1
+
+MY_PV="${PV:0:4}-${PV:4:2}-${PV:6:2}"
+MY_PN="Limnoria"
+MY_P="${MY_PN}-${MY_PV}"
+
+if [[ ${PV} == *9999 ]]; then
+	EGIT_REPO_URI="https://github.com/ProgVal/${MY_PN}.git"
+	EGIT_BRANCH="testing"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/ProgVal/${MY_PN}/archive/master-${MY_PV}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}/${MY_PN}-master-${MY_PV}"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="Python based extensible IRC infobot and channel bot"
+HOMEPAGE="https://docs.limnoria.net"
+LICENSE="BSD GPL-2 GPL-2+"
+SLOT="0"
+IUSE="crypt ssl test"
+RESTRICT=" !test? ( test )"
+
+RDEPEND="
+	dev-python/chardet[${PYTHON_USEDEP}]
+	dev-python/cryptography[${PYTHON_USEDEP}]
+	dev-python/ecdsa[${PYTHON_USEDEP}]
+	dev-python/feedparser[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+	dev-python/PySocks[${PYTHON_USEDEP}]
+	dev-python/sqlalchemy[${PYTHON_USEDEP}]
+	crypt? ( dev-python/python-gnupg[${PYTHON_USEDEP}] )
+	ssl? ( dev-python/pyopenssl[${PYTHON_USEDEP}] )
+	!net-irc/supybot
+	!net-irc/supybot-plugins"
+BDEPEND="test? ( dev-python/mock[${PYTHON_USEDEP}] )"
+
+python_prepare() {
+	einfo "Removing the RSS plugin because of clashes between libxml2's Python3"
+	einfo "bindings and feedparser."
+	rm -r "plugins/RSS" || die
+}
+
+python_test() {
+	pushd "${T}" > /dev/null || die
+	PLUGINS_DIR="${BUILD_DIR}"/lib/supybot/plugins
+	EXCLUDE_PLUGINS=()
+	# intermittent failure due to issues loading libsandbox.so from LD_PRELOAD
+	# runs successfully when running the tests on the installed system
+	EXCLUDE_PLUGINS+=( --exclude="${PLUGINS_DIR}/Unix" )
+	# Runs despite --no-network (GH #1392)
+	EXCLUDE_PLUGINS+=( --exclude="${PLUGINS_DIR}/Aka" )
+	"${EPYTHON}" "${BUILD_DIR}"/scripts/supybot-test "${BUILD_DIR}/../test" \
+		--plugins-dir="${PLUGINS_DIR}" --no-network \
+		--disable-multiprocessing "${EXCLUDE_PLUGINS[@]}" \
+		|| die "Tests failed under ${EPYTHON}"
+	popd > /dev/null || die
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	doman man/*
+}
+
+pkg_postinst() {
+	elog "Complete user documentation is available at https://limnoria-doc.readthedocs.org/"
+	elog ""
+	elog "Use supybot-wizard to create a configuration file."
+	elog "Run supybot </path/to/config> to use the bot."
+}