net-libs/glib-networking: bump to 2.62.3

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Mart Raudsepp <leio@gentoo.org>

1 files changed, 73 insertions, 0 deletions

diff --git a/net-libs/glib-networking/glib-networking-2.62.3.ebuild b/net-libs/glib-networking/glib-networking-2.62.3.ebuild
new file mode 100644
index 000000000000..8862fff92c3c
--- /dev/null
+++ b/net-libs/glib-networking/glib-networking-2.62.3.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit gnome.org gnome2-utils meson multilib-minimal xdg
+
+DESCRIPTION="Network-related giomodules for glib"
+HOMEPAGE="https://git.gnome.org/browse/glib-networking/"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+IUSE="+gnome +libproxy +ssl test"
+RESTRICT="!test? ( test )"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+
+RDEPEND="
+	>=dev-libs/glib-2.60.0:2[${MULTILIB_USEDEP}]
+	libproxy? ( >=net-libs/libproxy-0.4.11-r1:=[${MULTILIB_USEDEP}] )
+	>=net-libs/gnutls-3.4.6:=[${MULTILIB_USEDEP}]
+	ssl? ( app-misc/ca-certificates )
+	gnome? ( gnome-base/gsettings-desktop-schemas )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	>=sys-devel/gettext-0.19.8
+	>=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]
+	test? ( sys-apps/dbus )
+"
+
+multilib_src_configure() {
+	local emesonargs=(
+		-Dgnutls=enabled
+		-Dopenssl=disabled
+		$(meson_feature libproxy)
+		$(meson_feature gnome gnome_proxy)
+		-Dinstalled_tests=false
+		-Dstatic_modules=false
+	)
+	meson_src_configure
+}
+
+multilib_src_compile() {
+	meson_src_compile
+}
+
+multilib_src_install() {
+	meson_src_install
+}
+
+multilib_src_test() {
+	dbus-run-session meson test -C "${BUILD_DIR}" || die 'tests failed'
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	multilib_pkg_postinst() {
+		gnome2_giomodule_cache_update \
+			|| die "Update GIO modules cache failed (for ${ABI})"
+	}
+	multilib_foreach_abi multilib_pkg_postinst
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+
+	multilib_pkg_postrm() {
+		gnome2_giomodule_cache_update \
+			|| die "Update GIO modules cache failed (for ${ABI})"
+	}
+	multilib_foreach_abi multilib_pkg_postrm
+}