net-misc/tn5250: Bump eapi, stop using deprecated python eclass (python doesn't seem really needed as I see in Fedora package), drop .la files, fix deps.

Package-Manager: portage-2.3.0

1 files changed, 59 insertions, 0 deletions

diff --git a/net-misc/tn5250/tn5250-0.17.4-r1.ebuild b/net-misc/tn5250/tn5250-0.17.4-r1.ebuild
new file mode 100644
index 000000000000..c8457dee2428
--- /dev/null
+++ b/net-misc/tn5250/tn5250-0.17.4-r1.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+inherit eutils
+
+DESCRIPTION="Telnet client for the IBM AS/400 that emulates 5250 terminals and printers"
+HOMEPAGE="http://tn5250.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+IUSE="X libressl ssl"
+
+RDEPEND="
+	sys-libs/ncurses:=
+	ssl? (
+		!libressl? ( dev-libs/openssl:0= )
+		libressl? ( dev-libs/libressl:0= )
+	)
+"
+
+DEPEND="${RDEPEND}
+	X? ( x11-libs/libXt )
+"
+
+src_prepare() {
+	default
+	# Next, the Makefile for the terminfo settings tries to remove
+	# some files it doesn't have access to.	 We can just remove those
+	# lines.
+	cd "${S}/linux"
+	sed -i \
+		-e "/rm -f \/usr\/.*\/terminfo.*5250/d" Makefile.in \
+		|| die "sed Makefile.in failed"
+	cd "${S}"
+}
+
+src_configure() {
+	econf \
+		--disable-static \
+		--without-python \
+		$(use_with X x) \
+		$(use_with ssl)
+}
+
+src_install() {
+	# The TERMINFO variable needs to be defined for the install
+	# to work, because the install calls "tic."	 man tic for
+	# details.
+	dodir /usr/share/terminfo
+	emake DESTDIR="${D}" \
+		 TERMINFO="${D}/usr/share/terminfo" install
+
+	einstalldocs
+	prune_libtool_files
+}