net-misc/ntpclient: rename version for pkgrename

Upstream renamed ntpclient to sntpd.
Since old ntpclient is at version 2018_244, but new ntpd is at version
3.0, we need to rename old ntpclient to a lower version than 3.0.

This will trigger a rebuild due downgrade for affected users, but since
this is a small package, this shouldn't be much of a problem.

The changes will ensure, that the current stable version will continue
to work after pkgrename.

Package-Manager: Portage-3.0.4, Repoman-3.0.1
Signed-off-by: Conrad Kostecki <conikost@gentoo.org>

1 files changed, 36 insertions, 0 deletions

diff --git a/net-misc/ntpclient/ntpclient-2.2018.244-r1.ebuild b/net-misc/ntpclient/ntpclient-2.2018.244-r1.ebuild
new file mode 100644
index 000000000000..f6b938200cc1
--- /dev/null
+++ b/net-misc/ntpclient/ntpclient-2.2018.244-r1.ebuild
@@ -0,0 +1,36 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_PN="ntpclient"
+MY_PV="${PV/2./}"
+MY_P="${MY_PN}-${MY_PV/./_}"
+
+DESCRIPTION="A NTP (RFC-1305 and RFC-4330) client for unix-alike systems"
+HOMEPAGE="https://github.com/troglobit/sntpd"
+SRC_URI="https://github.com/troglobit/sntpd/releases/download/${MY_PV}/${MY_P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc x86"
+IUSE="debug embedded obsolete +syslog"
+
+S="${WORKDIR}/${MY_P}"
+
+PATCHES=(
+	"${FILESDIR}/${MY_PN}-${MY_PV}-linux-headers-5.2.patch"
+)
+
+src_configure() {
+	local myeconfargs=(
+		$(use_enable debug)
+		$(use_enable debug replay)
+		$(use_enable embedded mini)
+		$(use_enable obsolete)
+		$(use_enable !obsolete siocgstamp)
+		$(use_enable syslog)
+	)
+
+	econf "${myeconfargs[@]}"
+}