proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 56 insertions, 0 deletions

diff --git a/sys-apps/gnome-disk-utility/gnome-disk-utility-3.16.2.ebuild b/sys-apps/gnome-disk-utility/gnome-disk-utility-3.16.2.ebuild
new file mode 100644
index 000000000000..6436197271aa
--- /dev/null
+++ b/sys-apps/gnome-disk-utility/gnome-disk-utility-3.16.2.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+GCONF_DEBUG="no"
+GNOME2_LA_PUNT="yes"
+
+inherit autotools eutils gnome2
+
+DESCRIPTION="Disk Utility for GNOME using udisks"
+HOMEPAGE="http://git.gnome.org/browse/gnome-disk-utility"
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE="fat +gnome systemd"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86"
+
+COMMON_DEPEND="
+	>=dev-libs/glib-2.31:2
+	>=sys-fs/udisks-2.1.1:2
+	>=x11-libs/gtk+-3.12:3
+	>=app-arch/xz-utils-5.0.5
+	>=app-crypt/libsecret-0.7
+	dev-libs/libpwquality
+	systemd? ( >=sys-apps/systemd-44:0= )
+"
+RDEPEND="${COMMON_DEPEND}
+	>=media-libs/libdvdread-4.2.0
+	>=media-libs/libcanberra-0.1[gtk3]
+	>=x11-libs/libnotify-0.7:=
+	>=x11-themes/gnome-icon-theme-symbolic-2.91
+	fat? ( sys-fs/dosfstools )
+	gnome? ( >=gnome-base/gnome-settings-daemon-3.8 )
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-util/intltool-0.50
+	dev-libs/libxslt
+	gnome-base/gnome-common
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	# Fix USE=-gnome, bug #478820
+	epatch "${FILESDIR}"/${PN}-3.10.0-kill-gsd-automagic.patch
+	epatch "${FILESDIR}"/${PN}-3.10.0-raise-gsd-dependency.patch
+
+	eautoreconf
+	gnome2_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		$(use_enable gnome gsd-plugin) \
+		$(use_enable systemd libsystemd-login)
+}