sys-cluster/kubelet: 1.17.4 bump

Signed-off-by: William Hubbs <williamh@gentoo.org>

1 files changed, 43 insertions, 0 deletions

diff --git a/sys-cluster/kubelet/kubelet-1.17.4.ebuild b/sys-cluster/kubelet/kubelet-1.17.4.ebuild
new file mode 100644
index 000000000000..d32e9b53641a
--- /dev/null
+++ b/sys-cluster/kubelet/kubelet-1.17.4.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit go-module systemd
+
+DESCRIPTION="Kubernetes Node Agent"
+HOMEPAGE="https://github.com/kubernetes/kubernetes https://kubernetes.io"
+SRC_URI="https://github.com/kubernetes/kubernetes/archive/v${PV}.tar.gz -> kubernetes-${PV}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="hardened"
+
+DEPEND="dev-go/go-bindata
+	>=dev-lang/go-1.13"
+
+RESTRICT+=" test "
+S="${WORKDIR}/kubernetes-${PV}"
+
+src_prepare() {
+	default
+	sed -i -e "/vendor\/github.com\/jteeuwen\/go-bindata\/go-bindata/d"  -e "s/-s -w/-w/" hack/lib/golang.sh || die
+	sed -i -e "/export PATH/d" hack/generate-bindata.sh || die
+}
+
+src_compile() {
+	export CGO_LDFLAGS="$(usex hardened '-fno-PIC ' '')"
+	LDFLAGS="" emake -j1 WHAT=cmd/${PN} GOFLAGS=-v
+}
+
+src_install() {
+	dobin _output/bin/${PN}
+	keepdir /etc/kubernetes/manifests /var/log/kubelet /var/lib/kubelet
+	newinitd "${FILESDIR}"/${PN}.initd ${PN}
+	newconfd "${FILESDIR}"/${PN}.confd ${PN}
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}"/${PN}.logrotated ${PN}
+	systemd_dounit "${FILESDIR}"/${PN}.service
+	insinto /etc/kubernetes
+	newins "${FILESDIR}"/${PN}.env ${PN}.env
+}