sys-cluster/charliecloud: add 0.36, adapt live ebuild

Signed-off-by: Oliver Freyermuth <o.freyermuth@googlemail.com>
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

3 files changed, 96 insertions, 1 deletions

diff --git a/sys-cluster/charliecloud/Manifest b/sys-cluster/charliecloud/Manifest
index 5e9ba687e9fb..b96cef60a401 100644
--- a/sys-cluster/charliecloud/Manifest
+++ b/sys-cluster/charliecloud/Manifest
@@ -1,2 +1,3 @@
 DIST charliecloud-0.34.tar.gz 565976 BLAKE2B 0c86877bd3f17bf91d287f57b5e0844f7cb1777a499ea2bf67fb2cd5762f453239fe20afa6e4ba71acc98609c718028dd1e813a36aee881aa5c2cae79a65effd SHA512 5ede938a8015391758e0eef0b3661c12025cbac3e5153e2e5219fb4d50f8f78ac12076e4c3b658379a1521825372a0ed792a63210371cdbdad1e6631112e371d
 DIST charliecloud-0.35.tar.gz 585756 BLAKE2B ade539aa3f94055f84e1b6de73d0bea7739ab764c31399f25adbff82faa62c3ee7e8745aa74bb6e997d6723d002780339f48be8d7218462d3eb95ad119a2b8a8 SHA512 40f5e5891f0df8379b637c26c3d86b66a61b48ee1e7985260b47aa4abeffc77c3690af59ae38072b53f6dd348da4574249187ba922fc7c03fb74a513524dc08a
+DIST charliecloud-0.36.tar.gz 604778 BLAKE2B 671c7a95be7a0d3e772e3a02185f15c5e00df6d84f0c6a068b6ac2268eaf471c3dc8a9a445036110b564e44b906e4c1ba090474e0f75653d6e24a6270f2c332b SHA512 411fc4eded6d557460ef4688ee123c54939fdeea6799c7176f136d494986a643c4ef3cadc8079e995374a7988c73d32d160d6a3094e8184b491cb1985a18facd
diff --git a/sys-cluster/charliecloud/charliecloud-0.36.ebuild b/sys-cluster/charliecloud/charliecloud-0.36.ebuild
new file mode 100644
index 000000000000..2efe21c19d55
--- /dev/null
+++ b/sys-cluster/charliecloud/charliecloud-0.36.ebuild
@@ -0,0 +1,92 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit autotools optfeature python-single-r1
+
+if [[ ${PV} == "9999" ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/hpc/${PN}.git"
+	S="${WORKDIR}/${P}"
+else
+	SRC_URI="https://github.com/hpc/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86 ~x86-linux"
+fi
+
+DESCRIPTION="Lightweight user-defined software stacks for high-performance computing"
+HOMEPAGE="https://hpc.github.io/charliecloud/"
+
+SLOT="0"
+LICENSE="Apache-2.0"
+IUSE="ch-image doc"
+
+# Extensive test suite exists, but downloads container images
+# directly and via Docker and installs packages inside using apt/yum.
+# Additionally, clashes with portage namespacing and sandbox.
+RESTRICT="test"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	elibc_musl? ( sys-libs/argp-standalone )
+"
+DEPEND="
+	ch-image? (
+		$(python_gen_cond_dep '
+			dev-python/lark[${PYTHON_USEDEP}]
+			dev-python/requests[${PYTHON_USEDEP}]
+		')
+		dev-vcs/git
+		net-misc/rsync
+	)
+	doc? (
+		$(python_gen_cond_dep '
+			dev-python/sphinx[${PYTHON_USEDEP}]
+			dev-python/sphinx-rtd-theme[${PYTHON_USEDEP}]
+		')
+		net-misc/rsync
+	)"
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local econf_args=(
+		$(use_enable doc html)
+		$(use_enable ch-image)
+		# Libdir is used as a libexec-style destination.
+		--libdir="${EPREFIX}"/usr/lib
+		# Attempts to call python-exec directly otherwise.
+		--with-sphinx-python="${EPYTHON}"
+		# This disables -Werror, see also: https://github.com/hpc/charliecloud/pull/808
+		--enable-buggy-build
+		# Do not use bundled version of dev-python/lark.
+		--disable-bundled-lark
+		# Use correct shebang.
+		--with-python="${PYTHON}"
+		# Disable configure checks vor OverlayFS causing sandbox violations.
+		--disable-impolite-checks
+	)
+	econf "${econf_args[@]}"
+}
+
+src_install() {
+	docompress -x "${EPREFIX}"/usr/share/doc/"${PF}"/examples
+	default
+}
+
+pkg_postinst() {
+	elog "Various builders are supported, as alternative to the internal ch-image."
+	optfeature "Building with Buildah" app-containers/buildah
+	optfeature "Building with Docker" app-containers/docker
+	optfeature "Building with Podman" app-containers/podman
+	optfeature "Progress bars during long operations" sys-apps/pv
+	optfeature "Pack and unpack squashfs images" sys-fs/squashfs-tools
+	optfeature "Mount and umount squashfs images" sys-fs/squashfuse
+	optfeature "Build versioning with ch-image" dev-vcs/git
+}
diff --git a/sys-cluster/charliecloud/charliecloud-9999.ebuild b/sys-cluster/charliecloud/charliecloud-9999.ebuild
index 197f766fead6..2efe21c19d55 100644
--- a/sys-cluster/charliecloud/charliecloud-9999.ebuild
+++ b/sys-cluster/charliecloud/charliecloud-9999.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2023 Gentoo Authors
+# Copyright 1999-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -69,6 +69,8 @@ src_configure() {
 		--disable-bundled-lark
 		# Use correct shebang.
 		--with-python="${PYTHON}"
+		# Disable configure checks vor OverlayFS causing sandbox violations.
+		--disable-impolite-checks
 	)
 	econf "${econf_args[@]}"
 }