sys-kernel/gentoo-kernel-bin: bump to 5.4.137-r1 for arm64

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 114 insertions, 0 deletions

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index d64950558c2e..8b8a3a6429de 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -59,6 +59,7 @@ DIST gentoo-kernel-5.4.136-1.amd64.xpak 61421139 BLAKE2B 797b11e6719fd3800b27517
 DIST gentoo-kernel-5.4.136-1.arm64.xpak 57991376 BLAKE2B 8c5a8d30fe8362a0ea91efd4249b804d29d7ea436255b11f7379f12464cbeb0d25ffdb520f7aa0873e8d3522f9984c7946fa0e07a5f47251b55d3fb5c7297d39 SHA512 13008c837b323f9897627e3d091b1cfeea3443b62356c05413b7afff0a66ea3a4ab2d7cfa90a5b488a0f9ec938296a150bc43b12bc81e6c6a0b3d86033b7d99b
 DIST gentoo-kernel-5.4.136-1.x86.xpak 53155965 BLAKE2B dda19ed3567e9d97385a7fed5683c681405599177df084c085be0b02a946c9180ce23b970e26311738128a70312543eb768af9744fa1fdda2420bafd99a517d4 SHA512 905a8ab761771534f0d54af4843940c8695ed27225f68fa17187cf336da074c68e72e891f58205a9cf224a7d100eb84bf3ec1c50fd5a1070aa636823f9ea0115
 DIST gentoo-kernel-5.4.137-1.amd64.xpak 61351375 BLAKE2B 0ab9e813b74fa66eec713ca7ade8666f1d6e89f7b3a66c8a7cee2c56b07f6af3c7b7e1f000f32e73edc1e438adf8647ae441f731fc68c2cc38f9757286c5e66f SHA512 e2b640546e8bf46917c73277499e3c098a0400dfc1d34587d7942f1b3f6fa99e933ecda2308500f5a4b3f544082e5dcd243d94db05f6dc0dc0b1c2a24b06d5f4
+DIST gentoo-kernel-5.4.137-1.arm64.xpak 58029600 BLAKE2B e52bbf985127a0b1888862e0a7330da458e90fa87ec87ade63cf4c6dfd234959822f59aba6aff2967a7b86765651faebd43bd68040d685571890703f84120e93 SHA512 30a4de2040b8e094cbf0a7186040551302523b628aa6749fbecd425b6f4ff90e1ba95582eb95962c521654429a939d05ca957b151bf9c6201692a7c41debe99d
 DIST gentoo-kernel-5.4.137-1.x86.xpak 53152996 BLAKE2B 640fb56116dc7eec0af1746d491a9e201914ed6831cf98a588c14a116e0d6164da5458bb3798d4e25df85d6e2f515b4eaae710e99521b5b17579b17d3fa7f648 SHA512 da4ce341561f6c24239efa905b7afc17467cb97b4c23b10cefbcad8483055ebeefbe422339eb66d2a9837300e6d1bd5405510189119e848ef45217a744b65bed
 DIST linux-5.10.tar.xz 116606704 BLAKE2B b923d7b66309224f42f35f8a5fa219421b0a9362d2adacdadd8d96251f61f7230878ea297a269a7f3b3c56830f0b177e068691e1d7f88501a05653b0a13274d1 SHA512 95bc137d0cf9148da6a9d1f1a878698dc27b40f68e22c597544010a6c591ce1b256f083489d3ff45ff77753289b535135590194d88ef9f007d0ddab3d74de70e
 DIST linux-5.12.tar.xz 118112412 BLAKE2B 842d921b9a73d2aaade763dbd2ec67bdfe0275baa6d628b775f5c87574ad7dc86f0419afcd48c10c1235f4bffa16084243f2cf4556e6afcd391e975fe8ba530b SHA512 be03b6fee1d1ea8087b09874d27c0a602c0b04fd90ad38b975bd2c8455a07e83c29b56814aaf1389e82305fae0e4c2d1701075a7f0a7295dd28149f967ec5b3d
diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.137-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.137-r1.ebuild
new file mode 100644
index 000000000000..fe6e6023d323
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.137-r1.ebuild
@@ -0,0 +1,113 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 4 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}