sys-kernel/gentoo-kernel-bin: bump to 5.13.10-r1 for arm64

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 114 insertions, 0 deletions

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index f613525b9e14..b28b1e8779a9 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -67,6 +67,7 @@ DIST gentoo-kernel-5.12.19-1.amd64.xpak 66346655 BLAKE2B a03cbcdcd1a90d48d7e11e9
 DIST gentoo-kernel-5.12.19-1.arm64.xpak 60043529 BLAKE2B 8746081847a39e1847b8e9f35fcd68565370b116d6418edf803c4cdca9d750ac8ada58c4a7fd377480a1c75b3c805864d419c02ee21675bc77ac195731385a18 SHA512 d1a8a9210a1ab3d3c1894be1fe524e64b859b0a02763feacfed1a24655540ade6c28af751b23e924fcc04fb9abd56e84c43d634ad80bbb4d5de79ed533b5ea50
 DIST gentoo-kernel-5.12.19-1.x86.xpak 58076509 BLAKE2B 0e4aca91c834b23fb169bb6fabab13130de811c15f89e6341ad2a36ac230071ced6c6d7bd30be0f0f3860d09968449c1933cd33ed021213c667304070b80f9a7 SHA512 9786f106ed59661546d9f035e25c39f4c7a4a41f51afa96700867e47bab19e148e8a42c79bc3b7780967c2f82f1fef6920f220fb5fccd6f267a2c6e6a3081126
 DIST gentoo-kernel-5.13.10-1.amd64.xpak 67265148 BLAKE2B 834bbccb256b81be3baef78f53a3ab38a228c3090b3fdc93e7b95cd31877cf16f80fe63ad9448f0921cc6d36cc0508daac88b90aa1004304b6cdcd5b17198a5d SHA512 33898bf8a51fa576aa7b39dca494ec191725d5160ef6366df2deb64a11067c6403dfa320b5817b62f35bbc8c76d8bcd8f4a6844b97c27de6b3d756ed4ae05ae3
+DIST gentoo-kernel-5.13.10-1.arm64.xpak 62771380 BLAKE2B 59773ce3ff9db43dbf8e120eef8f1cdd0b73f1107fa418dd293e225916455e31124409ddedea8b59f7a1b2ddb8c2abc3002d8164dcdf2983c8d2050f03c98a71 SHA512 5c15119feecbbef1905840c3867b3624cb172c5ffd6634ebbac32d7952ee8a3cc747e0021ca70604ceb050eb76ed2f427c9ef3d5655dd08de4891c2fd8f4fb01
 DIST gentoo-kernel-5.13.10-1.x86.xpak 58503973 BLAKE2B 8b10972522c16da49313987b08d34a9597cac4cf4218b08e50a899b48f2806f1a3dd7e913cd2a505e415bc7d7c6daf5d0262bcc5e23a1bfc4ef41b674d2b77c2 SHA512 61b1073e12788f9086ba074dfd880695c5a73adeb1e03cb3afd5e50af60d231b107d5618d812ba6bf0158da2953b138b7d5cdedd89c6d4a6d5e116e9b49a82fb
 DIST gentoo-kernel-5.13.4-1.arm64.xpak 62698454 BLAKE2B 110da7beab919c6a3c95cae947afa030cb4aa9483fbe39f416a7ef391c70904f99f129089b7b7b5c197b2372cabebe751f5451b7daa7544153e8cb6c7c2dcb3b SHA512 e8b7a6250fbb9b71af6eb58926d7127bf48df1dc1cd669089723c3b9641dc71df15072b3e973a6d75ec053cbe0b7aad4bfa8da67544f564fe095a93fbc35e5c6
 DIST gentoo-kernel-5.13.4-2.amd64.xpak 67284746 BLAKE2B 945d5bb6271142f32f421702969ebffe70ca5232f54bd8a1b48a559971510eb623e7a9b803b044cd17273d27606ad37744e8fbd2812cacf46973f3152ee91939 SHA512 af4cb262af32136138754401682de9f7c781929a0a950d2453738300025b06973a3001d1f2c23496e04a3367f12e07ef897ff858ca9325de59309924c04fdc98
diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.13.10-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.13.10-r1.ebuild
new file mode 100644
index 000000000000..56164dd0991a
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.13.10-r1.ebuild
@@ -0,0 +1,113 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 2 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+		-> ${BINPKG}.arm64.xpak
+	)"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}