sys-kernel/gentoo-kernel-bin: bump to 5.12.9 for arm64

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 116 insertions, 0 deletions

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 6a1b5d29f1a2..d2a770cd1aa7 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -63,6 +63,7 @@ DIST gentoo-kernel-5.12.8-1.amd64.xpak 66367297 BLAKE2B adadd41d205de9376e4f2c7c
 DIST gentoo-kernel-5.12.8-1.arm64.xpak 59934047 BLAKE2B f2ecf71fe91aaad771ef380e029d419114dc13133a1021d378dd89c70ea3f31b88e445da2a110bff43d43c75446fbfce753aa13008977f2a9f795d1c767507e5 SHA512 cb0fe3d3937739dd2f218d895f6c9185f71606d3016a15020703e03e97d2903a0b3865a0751811f6771f9a367f68e0fc36a56b667cf21ae2e673e6e86d934114
 DIST gentoo-kernel-5.12.8-1.x86.xpak 58087343 BLAKE2B 11d7693cf474bf9b736e2c347831da8208475c1ecc09a9a974fb4512f941c98108379bbca25011a2f2dfb7a229a69a39c69e5687947744edf20e3e6d7193b0c3 SHA512 409aeefe20ed363b7b7bf944707c884c963afb7054767ba6793ad889ac3edfc698234d8b8bef2e7ab708c529178905ce7aec877e3c35e3976545b4aa0e5ab838
 DIST gentoo-kernel-5.12.9-1.amd64.xpak 66361019 BLAKE2B 179b6c33014af458d28277bb1cf0e05952ce6d544f0f8388c29938fa1ce0a50fe019f117017276c5d06540828ea31391d214bfcdcbbac04c5c92aee8df16b013 SHA512 97b1b2d61b01878cc29890584dd83190374b1bf8692268c417366ffe63f76d5875b0be2e99823eb2bcdc45755638664f8721458240671fe907f06fd320dde8f5
+DIST gentoo-kernel-5.12.9-1.arm64.xpak 60205103 BLAKE2B b973cbced9a31c988a0e7ab8bc3926eddd447f3676969c022608fc90d5d8b7e4ce207558b77dcd0ec8a09d25bfa169e2ca357314ac9dd3378a3f6b64fc4c43b8 SHA512 d4781af4d03219a4e187da07dd71a0487c909fa8b00dbbd569d290b8ec01e67fd57901a87bb042d4244f24377181cb4dabf4bef1c8b99225d477384a614bb0f4
 DIST gentoo-kernel-5.12.9-1.x86.xpak 58104639 BLAKE2B 145a490565efd5926bed22faf66f1bff756bab880a5a890f2a9e25e31c39489d38621718a1225289cea9e81dc609e232531a832b65ba76a7aa8be8eabba85904 SHA512 b6842920e12306f14180812aa5d841dec91d221cc00374d1cf694ccd1a139233e5ccacbe06ca7c0540fc04c9c1228f9e796172941a7f7265b503209442cee668
 DIST gentoo-kernel-5.4.115-1.amd64.xpak 61381562 BLAKE2B e36468cb61a73daffd9709bc8e13eb1c11a0ec1e8f68df55c07eaa50e7538337534ca48342b019b308c99c121628f55c868a5577b2c1a5a4a67cdd72a6fea8ef SHA512 5bb1836cfd7b746aa5d8e947d6fe63c368f86a0d439e56106a77b3f3c3999d3761f238bfd76b5785035ff68869da271a2c3a4dfb5f09fb16b343e0d296ad9d60
 DIST gentoo-kernel-5.4.115-1.arm64.xpak 56473345 BLAKE2B ba662f7d08629dc4fd8978de1db9f0f4400cde21802590a168f9737da03013e27c09a5ecbadcc99f482c935f20db61f9395bc006390b46bea45af305f1677620 SHA512 2ee5adf31d0a8c2bfa76cfadd5c56e818cf31cea3323c91517cd752ce4c87256c2a4f33583119977e37538669d5e2046f77fdd0b9c6adf15ccc498e7179a2088
diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.12.9-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.12.9-r1.ebuild
new file mode 100644
index 000000000000..9cc54d1c175f
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.12.9-r1.ebuild
@@ -0,0 +1,115 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 1 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)
+"
+
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}