sys-kernel/gentoo-kernel-bin: bump to 5.4.115 for arm64

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 115 insertions, 0 deletions

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 1f318f87f8ba..dbbf8c82bacc 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -89,6 +89,7 @@ DIST gentoo-kernel-5.4.114-1.amd64.xpak 61383665 BLAKE2B 54805c103f9be50fc636b7d
 DIST gentoo-kernel-5.4.114-1.x86.xpak 53172196 BLAKE2B d11355419540bb3149a6f9b1f9d8af340fbdf4f3e9bfb4fbd99a03de508e91b49534258dbbcebfaa48aa25b03093556bb5c3f440a639d3982f3b60f30754c85b SHA512 2b2ac728cfa27666bcdcb7bd1bebe8800f407796a645028820a549c74e1f17095929ae9eae05f2b31700899cbb328a3b588912e435d096af8d712c8008b7428a
 DIST gentoo-kernel-5.4.114-2.arm64.xpak 56441576 BLAKE2B 1eac86f2b8e73c69f018fddc276699bf6cee7719828f0c740cbe075dc9edccd80ecbb79da9c3cba4bb95d8a1903127c315b4a42b785e2933d4eb2efb2b2e163e SHA512 cdff3b3c277cc3a248e636a609ce60bf9d94465a73f96a1d38a77743f61898d2e848d3377526cb4c5e9292ff2755e67b5e93dfbc18653da71dcbbe1f70cde8d4
 DIST gentoo-kernel-5.4.115-1.amd64.xpak 61381562 BLAKE2B e36468cb61a73daffd9709bc8e13eb1c11a0ec1e8f68df55c07eaa50e7538337534ca48342b019b308c99c121628f55c868a5577b2c1a5a4a67cdd72a6fea8ef SHA512 5bb1836cfd7b746aa5d8e947d6fe63c368f86a0d439e56106a77b3f3c3999d3761f238bfd76b5785035ff68869da271a2c3a4dfb5f09fb16b343e0d296ad9d60
+DIST gentoo-kernel-5.4.115-1.arm64.xpak 56473345 BLAKE2B ba662f7d08629dc4fd8978de1db9f0f4400cde21802590a168f9737da03013e27c09a5ecbadcc99f482c935f20db61f9395bc006390b46bea45af305f1677620 SHA512 2ee5adf31d0a8c2bfa76cfadd5c56e818cf31cea3323c91517cd752ce4c87256c2a4f33583119977e37538669d5e2046f77fdd0b9c6adf15ccc498e7179a2088
 DIST gentoo-kernel-5.4.115-1.x86.xpak 53174038 BLAKE2B 497eafe82f52493f8fb9c9703be26f6df39a8e7f5d123c8e26f46b53c6d13531674da658d965d50159e52275c1c91490136372bc14828a90164bb21aa8ccbf32 SHA512 c10f98b0160f5809aa734c9e74f189e9d55ea5e4b568a9fa6d1d269606d683dd117c193cea412d61ac9899b2690ac364a2f57a16582c58ed512386e78d029b8b
 DIST gentoo-kernel-5.4.116-1.amd64.xpak 61373865 BLAKE2B f2868de00d60fcc3dbcf6fc7afa2b15bd8b4565b4816880799e9af75ff9f48d2318162b5e245aea5d88d6542a06b10ee0e0aec3424272a1999360d80686896f5 SHA512 18c64132b59135c7c9795a396617b3219b35ba8feebac4a71144275c08e2985038328caf025aaa1eec3c49f59e5a4739f30909497d34e4dc09e842f53ed810ac
 DIST gentoo-kernel-5.4.116-1.x86.xpak 53182632 BLAKE2B 7fa5f8eaa056bae7438488df24870f25c411190f0bfc1822de0d6369f7a0aaecc1791df4ca596137bd2eea694d88407b3b1303766c423592033c8a2ebf1416da SHA512 f3d70d2479009a7c1174c6ae3e8acddc069b4132c315e9a122fb4d7441eb7e6fc18564d84343af4ed931ea2fb03c46b911d7d5ef4f1951f7de48b7f56bf6ef34
diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.115-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.115-r1.ebuild
new file mode 100644
index 000000000000..b63276300c50
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.115-r1.ebuild
@@ -0,0 +1,114 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 3 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)
+"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}