sys-kernel/gentoo-kernel-bin: bump to 5.8.12 for arm64

Package-Manager: Portage-3.0.4, Repoman-3.0.1
Signed-off-by: Sam James <sam@gentoo.org>

1 files changed, 53 insertions, 0 deletions

diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.8.12-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.8.12-r1.ebuild
new file mode 100644
index 000000000000..dca6aedbd789
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.8.12-r1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install
+
+MY_P=${P/-bin/}-1
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	amd64? (
+		https://dev.gentoo.org/~mgorny/binpkg/amd64/kernel/sys-kernel/gentoo-kernel/${MY_P}.xpak
+			-> ${MY_P}.amd64.xpak
+	)
+	x86? (
+		https://dev.gentoo.org/~mgorny/binpkg/x86/kernel/sys-kernel/gentoo-kernel/${MY_P}.xpak
+			-> ${MY_P}.x86.xpak
+	)"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}
+	!sys-kernel/vanilla-kernel:${SLOT}
+	!sys-kernel/vanilla-kernel-bin:${SLOT}"
+
+QA_PREBUILT='*'
+
+pkg_pretend() {
+	ewarn "Starting with 5.7.9, Distribution Kernels are switching from Arch"
+	ewarn "Linux configs to Fedora.  Please keep a backup kernel just in case."
+
+	kernel-install_pkg_pretend
+}
+
+src_unpack() {
+	ebegin "Unpacking ${MY_P}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${MY_P}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${MY_P} failed"
+}
+
+src_test() {
+	kernel-install_test "${PV}" \
+		"${WORKDIR}/usr/src/linux-${PV}/$(kernel-install_get_image_path)" \
+		"lib/modules/${PV}"
+}
+
+src_install() {
+	mv * "${ED}" || die
+}