sys-kernel/gentoo-kernel-bin: bump to 5.4.140-r1 for arm64

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 114 insertions, 0 deletions

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 7cc2ca84aef8..77a11bc7e2c2 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -104,6 +104,7 @@ DIST gentoo-kernel-5.4.139-1.amd64.xpak 61366933 BLAKE2B 27ae32ce446930ba96fab8b
 DIST gentoo-kernel-5.4.139-1.arm64.xpak 57992677 BLAKE2B b194275b4c4e5fc42a20a74f47c300c3ec3b26f6f02ac75ca8ea9b2b582153bc2922f9a525e5e2d005d74e9fa91b5013649cb96f40624985a6ab47d941967f70 SHA512 f7214dfa120ff96e8d6f327c79ef59d8bbbfd9c7c1b3236fb531f04cc0340f7d4dc8745740bd7c0edcdeacd23449cc73c0d415ae3fe8100f589aa2cef4901f3a
 DIST gentoo-kernel-5.4.139-1.x86.xpak 53173145 BLAKE2B e516100fcd8f4f52df93deb22939ae24f59d67ffe797c79cf7a91b36ce76df04f7ef52b158b2f94cbb2c9c9534d0405fb936243548f8759f05ee096c7d93ed36 SHA512 a464719010c35edeb307e1004fb97d7d3be5e8dc143219697081fe73f1812fe57f316a6ed97db86147ffda10bad16b18d1e753c0360d778d6354e6d4876d7f0f
 DIST gentoo-kernel-5.4.140-1.amd64.xpak 61369693 BLAKE2B 5f869206ad8102cca2e6cc72237ae026763bae7450fc90009a78439789f958cbc133ac5f8a207caf7c0d59c71df124c9fd6de4805ea4a4e701902f7fb44a4ddf SHA512 ceae6f100fe5a28d87fd32daac43d43c3e52a6bd96dd4fbcf73b5593ed21f4641e0ded5e55eb2b443b212bd312a0550f5020ebe34b94504f16e1ad905e077c70
+DIST gentoo-kernel-5.4.140-1.arm64.xpak 57965446 BLAKE2B 560b269104ff385823bfe067483d44440c6cc3bce3e41b1a156316e9af57b9bd9a2d1fcc8f7b698a330bde5c926e2c0e6f61d372085e79aee02e97295b1c7cbf SHA512 74c346964e6b21cd1073140b4e0559ba2fd166a73696d091d09c8656ce95c08f89662a70344deb0806c3b4cb14c081418abfae8d4442fbc792c2f7958f51e510
 DIST gentoo-kernel-5.4.140-1.x86.xpak 53160196 BLAKE2B 9230edc3d36d4aae621bbdf79262b824a8b9810c7a253b4b09ba7bc0974baedb53f43c70fd6cfaf67b470a50f82fb119a7cf33d425f63e9e50fca4a9570c322f SHA512 29aa547d20e415a50738b3615f25c9f4ebddbcd8d4e9db43aaa8651f40b1e1a93f953ba66963a3c0ba3cdd46d259a638107711e0d3830013359e34346ccf78ea
 DIST linux-5.10.tar.xz 116606704 BLAKE2B b923d7b66309224f42f35f8a5fa219421b0a9362d2adacdadd8d96251f61f7230878ea297a269a7f3b3c56830f0b177e068691e1d7f88501a05653b0a13274d1 SHA512 95bc137d0cf9148da6a9d1f1a878698dc27b40f68e22c597544010a6c591ce1b256f083489d3ff45ff77753289b535135590194d88ef9f007d0ddab3d74de70e
 DIST linux-5.12.tar.xz 118112412 BLAKE2B 842d921b9a73d2aaade763dbd2ec67bdfe0275baa6d628b775f5c87574ad7dc86f0419afcd48c10c1235f4bffa16084243f2cf4556e6afcd391e975fe8ba530b SHA512 be03b6fee1d1ea8087b09874d27c0a602c0b04fd90ad38b975bd2c8455a07e83c29b56814aaf1389e82305fae0e4c2d1701075a7f0a7295dd28149f967ec5b3d
diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.140-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.140-r1.ebuild
new file mode 100644
index 000000000000..fe6e6023d323
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.140-r1.ebuild
@@ -0,0 +1,113 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 4 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}