sys-power/sispmctl: Version 4.1

- EAPI=7
- Remove obsolete USE=gemplug (bug #632476)
- Add USE=static-libs (bug #725974) and drop .la file
- Do not install empty NEWS
- Use udev.eclass to install rules file
- Install systemd thingamy

Package-Manager: Portage-2.3.100, Repoman-2.3.22
Closes: https://bugs.gentoo.org/632476
Closes: https://bugs.gentoo.org/725974
Signed-off-by: Jeroen Roovers <jer@gentoo.org>

1 files changed, 46 insertions, 0 deletions

diff --git a/sys-power/sispmctl/sispmctl-4.1.ebuild b/sys-power/sispmctl/sispmctl-4.1.ebuild
new file mode 100644
index 000000000000..693002dbfb70
--- /dev/null
+++ b/sys-power/sispmctl/sispmctl-4.1.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit bash-completion-r1 systemd udev user
+
+DESCRIPTION="GEMBIRD SiS-PM control utility"
+HOMEPAGE="http://sispmctl.sourceforge.net/"
+SRC_URI="mirror://sourceforge/sispmctl/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="static-libs"
+
+RDEPEND="
+	virtual/libusb:0
+"
+DEPEND="
+	${RDEPEND}
+"
+DOCS="AUTHORS README ChangeLog"
+
+pkg_setup() {
+	enewgroup ${PN}
+}
+
+src_configure() {
+	econf \
+		$(use_enable static-libs static) \
+		--enable-webless
+}
+
+src_install() {
+	default
+
+	find "${ED}" -name '*.la' -delete || die
+
+	## install udev rules which make the device files writable
+	## by the members of the group sispmctl
+	udev_dorules examples/60-sispmctl.rules
+
+	systemd_dounit examples/${PN}.service
+
+	einfo "Add users who may run ${PN} to the group '${PN}'"
+}