proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 56 insertions, 0 deletions

diff --git a/www-apps/baikal/baikal-0.2.7.ebuild b/www-apps/baikal/baikal-0.2.7.ebuild
new file mode 100644
index 000000000000..e2738a285bbe
--- /dev/null
+++ b/www-apps/baikal/baikal-0.2.7.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+
+inherit webapp
+
+DESCRIPTION="Lightweight CalDAV+CardDAV server"
+HOMEPAGE="http://baikal-server.com/"
+SRC_URI="http://baikal-server.com/get/${PN}-regular-${PV}.tgz"
+
+LICENSE="GPL-3"
+KEYWORDS="~amd64"
+IUSE="+mysql sqlite"
+REQUIRED_USE="|| ( mysql sqlite )"
+
+RDEPEND=">=dev-lang/php-5.3[ctype,filter,pdo,session,xml,mysql?,sqlite?]
+	mysql? ( virtual/mysql )
+	sqlite? ( dev-db/sqlite )
+	virtual/httpd-php"
+
+S=${WORKDIR}/${PN}-regular
+
+src_install() {
+	webapp_src_preinst
+
+	dodoc *.md  || die "dodoc failed"
+
+	einfo "Installing web files"
+	insinto "${MY_HTDOCSDIR}"
+	doins -r html/* html/.htaccess Core vendor || die "doins failed"
+
+	einfo "Setting up container for configuration"
+	insinto /etc/${PN}
+	doins Specific/.htaccess || die "doins failed"
+
+	einfo "Fixing symlinks"
+	local link target
+	find "${D}${MY_HTDOCSDIR}" -type l | while read link ; do
+		target=$(readlink "${link}")
+		target=${target/..\/Core/Core}
+		rm "${link}" && ln -s "${target}" "${link}"
+	done
+	dosym /etc/${PN} "${MY_HTDOCSDIR}"/Specific
+	dosym . "${MY_HTDOCSDIR}"/html
+
+	webapp_postinst_txt en "${FILESDIR}/postinstall-en.txt"
+	webapp_src_install
+
+	if has_version www-servers/apache ; then
+		fowners -R apache:apache /etc/${PN}
+	else
+		einfo "/etc/${PN} must be owned by the webserver user for baikal"
+	fi
+}