www-client/opera-beta: bump to 80.0.4170.7

Package-Manager: Portage-3.0.20, Repoman-3.0.3
Signed-off-by: Stephan Hartmann <sultan@gentoo.org>

2 files changed, 158 insertions, 0 deletions

diff --git a/www-client/opera-beta/Manifest b/www-client/opera-beta/Manifest
index 4d662403c8f7..aff2a465144c 100644
--- a/www-client/opera-beta/Manifest
+++ b/www-client/opera-beta/Manifest
@@ -1,5 +1,6 @@
 DIST opera-beta_79.0.4143.15_amd64.deb 77600048 BLAKE2B 8f1e1889a3f38d70b77ed3f27d61e987d1cabd36cdfa2dae87febe946a70bb17e11a1b63c1d1cbafcfb3e16b69ecc7cafcb16879fe1ae7c6e311af425e96456a SHA512 4b7330ae98e1445041370736f88eb468daaf9a4c6d244004cdb5e335dd0f970344015f1f379e3a40fb62dbda606b2722e4f2f7d6b1c2651ad2c49db11697f5bd
 DIST opera-beta_79.0.4143.19_amd64.deb 77588480 BLAKE2B d55e0621fc26d4de8708da8084a43cd2d4893a5273d1420f09fa2e37e4a2bda5242aadcdc7a3f8b965b167d22852ededde3e60d69f906ebd6bbbba1fda6d0abb SHA512 9f75b8d66977eddeb50474115f8d11f61eee8235c98b1e28dcb95ad4c295fc340237d0ad1a3e64e73c84dbe7003618dd10a9c2ec39884a1d34199e3c9715d83a
 DIST opera-beta_80.0.4170.4_amd64.deb 80037964 BLAKE2B 040be729ef754438a793abca7ee448ab6eefa5929c75f09f8881a5a646efd4a301d27db35d3c02a54d2064c86e1279050dcc02c30af70de5b64bfe937ac07767 SHA512 00461d53d59ea3d5f0a5dabe7c70fa0e6e38d04fcd7e28106c1d6463ef75e9f1f2a501245e5eb603e3638cf38ee2b8055155802ae6ed05f993bb75d5b13c1968
+DIST opera-beta_80.0.4170.7_amd64.deb 80013760 BLAKE2B 8490351b1eaf05dea8d058074ef28dba00927805da669d958351893b28a54f560b21446f840db60553f32d5f2cfa4180374543ea8e1359f66495107270ebc980 SHA512 fdeeb2ea94429bc8aae0cdf5c59993fdc8b024e56e8ec58ed04a9dcebe3d7c1028b7b9fe4f51898354bb797fa9594cfccf64b3dcdd548c78f3567c9d02ebfcc2
 DIST opera-ffmpeg-codecs-93.0.4573.0.tar.xz 1389664 BLAKE2B 4efc7341655bed294d4c6237dd9e7d005a815c495a45bec6f0b7fcbec40345e22ad5199ec1db3c822c123663d3ce95e6b87af18b1ac6cad31793ae7fdb440918 SHA512 f7c62c6860d1440e91344c41d6c9b3fbef4745cb95262538dcb3af9147406b3b0c71e72605042c423cbdd618a53f902791bcb6b7fcc8a4cae92ebf3cb38e8407
 DIST opera-ffmpeg-codecs-94.0.4603.0.tar.xz 1388572 BLAKE2B 55a598883dfbab598f48a662009ab02c4974a95ba023e3b2d36bdad3267ab4586cfd05891f83a96933b6b0b02dc1d2a496bb796ecb5421635a370f6c79c60a98 SHA512 dfeb7174ad5d696f78a86735462757d0245aecf0d00c21ba6ff3c16f6af586979457ebb23db228f3769cf09636ed70421aafe29eb622ca658e766dafc860827a
diff --git a/www-client/opera-beta/opera-beta-80.0.4170.7.ebuild b/www-client/opera-beta/opera-beta-80.0.4170.7.ebuild
new file mode 100644
index 000000000000..bf0853a5f751
--- /dev/null
+++ b/www-client/opera-beta/opera-beta-80.0.4170.7.ebuild
@@ -0,0 +1,157 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+CHROMIUM_LANGS="
+	be bg bn ca cs da de el en-GB en-US es-419 es fil fi fr-CA fr hi hr hu id
+	it ja ko lt lv ms nb nl pl pt-BR pt-PT ro ru sk sr sv sw ta te th tr uk vi
+	zh-CN zh-TW
+"
+
+# These are intended for ebuild maintainer use to force RPM if DEB is not available.
+: ${OPERA_FORCE_RPM=no}
+
+if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+	OPERA_UNPACKER="rpm"
+	OPERA_ARCHIVE_EXT="rpm"
+else
+	OPERA_UNPACKER="unpacker"
+	OPERA_ARCHIVE_EXT="deb"
+fi
+
+inherit chromium-2 multilib pax-utils ${OPERA_UNPACKER} xdg
+
+DESCRIPTION="A fast and secure web browser"
+HOMEPAGE="https://www.opera.com/"
+LICENSE="OPERA-2018"
+SLOT="0"
+
+SRC_URI_BASE=(
+	"https://download1.operacdn.com/pub/${PN}"
+	"https://download2.operacdn.com/pub/${PN}"
+	"https://download3.operacdn.com/pub/${PN}"
+	"https://download4.operacdn.com/pub/${PN}"
+)
+
+if [[ ${PN} == opera ]]; then
+	MY_PN=${PN}-stable
+	SRC_URI_BASE=( "${SRC_URI_BASE[@]/%//desktop}" )
+else
+	MY_PN=${PN}
+fi
+
+KEYWORDS="-* ~amd64"
+
+FFMPEG_VERSION="94.0.4603.0"
+
+SRC_URI="${SRC_URI_BASE[@]/%//${PV}/linux/${MY_PN}_${PV}_amd64.${OPERA_ARCHIVE_EXT}}
+	proprietary-codecs? (
+		mirror+https://dev.gentoo.org/~sultan/distfiles/www-client/opera/opera-ffmpeg-codecs-${FFMPEG_VERSION}.tar.xz
+	)"
+
+IUSE="+proprietary-codecs suid"
+RESTRICT="bindist mirror strip"
+
+RDEPEND="
+	app-accessibility/at-spi2-atk:2
+	app-accessibility/at-spi2-core:2
+	dev-libs/atk
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	gnome-base/gsettings-desktop-schemas
+	media-libs/alsa-lib
+	media-libs/mesa[gbm(+)]
+	net-misc/curl
+	net-print/cups
+	sys-apps/dbus
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3
+	x11-libs/libdrm
+	x11-libs/libxcb
+	x11-libs/libxkbcommon
+	x11-libs/libxshmfence
+	x11-libs/libX11
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXrandr
+	x11-libs/pango
+"
+
+QA_PREBUILT="*"
+S=${WORKDIR}
+OPERA_HOME="opt/opera${PN#opera}"
+
+pkg_pretend() {
+	# Protect against people using autounmask overzealously
+	use amd64 || die "opera only works on amd64"
+}
+
+pkg_setup() {
+	chromium_suid_sandbox_check_kernel_config
+}
+
+src_unpack() {
+	:
+}
+
+src_install() {
+	dodir /
+	cd "${ED}" || die
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		rpm_src_unpack "${A[0]}"
+	else
+		unpacker
+	fi
+
+	# move to /opt, bug #573052
+	mkdir -p "${OPERA_HOME%${PN}}"
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		mv "usr/lib64/${PN}" "${OPERA_HOME%${PN}}" || die
+	else
+		mv "usr/lib/x86_64-linux-gnu/${PN}" "${OPERA_HOME%${PN}}" || die
+	fi
+	rm -r "usr/lib" || die
+
+	# disable auto update
+	rm "${OPERA_HOME}/${PN%-*}_autoupdate"{,.licenses,.version} || die
+
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		rm "${OPERA_HOME}/setup_repo.sh" || die
+	else
+		rm -r "usr/share/lintian" || die
+
+		# fix docs
+		mv usr/share/doc/${MY_PN} usr/share/doc/${PF} || die
+		gzip -d usr/share/doc/${PF}/changelog.gz || die
+	fi
+
+	# fix desktop file
+	sed -i \
+		-e 's|^TargetEnvironment|X-&|g' \
+		usr/share/applications/${PN}.desktop || die
+
+	# remove unused language packs
+	pushd "${OPERA_HOME}/localization" > /dev/null || die
+	chromium_remove_language_paks
+	popd > /dev/null || die
+
+	# setup opera symlink
+	rm "usr/bin/${PN}" || die
+	dosym "../../${OPERA_HOME}/${PN}" "/usr/bin/${PN}"
+
+	# install proprietary codecs
+	rm "${OPERA_HOME}/resources/ffmpeg_preload_config.json" || die
+	if use proprietary-codecs; then
+		mv lib_extra "${OPERA_HOME}"
+	fi
+
+	# pax mark opera, bug #562038
+	pax-mark m "${OPERA_HOME}/opera"
+	# enable suid sandbox if requested
+	use suid && fperms 4711 "${OPERA_HOME}/opera_sandbox"
+}