www-client/opera-developer: automated bump (91.0.4484.0)

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 159 insertions, 0 deletions

diff --git a/www-client/opera-developer/Manifest b/www-client/opera-developer/Manifest
index fd7fab7132c8..4d3a0005ec62 100644
--- a/www-client/opera-developer/Manifest
+++ b/www-client/opera-developer/Manifest
@@ -1,4 +1,5 @@
 DIST opera-developer_90.0.4463.0_amd64.deb 87029836 BLAKE2B 01288f6d89081c584104425ce83f0e87a8a74db82b0fca299c5804315812388f8ddf0db99375e3771972721efe4d954416f00d9723c07f8abadb4a3e4673d6ec SHA512 b14574022bdb91a20a8daf5bb7a9e622a4874dcd0219c15ebba1b4c56fc8e4fe4621d42e3a1154180aeb4478ca395cd6641ce89dda2b40cb917807b584bbfb55
 DIST opera-developer_90.0.4470.0_amd64.deb 87647176 BLAKE2B 86f8b4ae3d346a314078429aeb1070ecf31d007b46c890e5c013d697dceabe5dbf7e4e312f22e54da8215c87da6c8e2524ffdb6bec9a826514c018117c4c6b51 SHA512 9bd48def6804a6cf173e738e2297619401748339971ca031c3af1d6dc820e25777972c6691c560d506b97c3af0c1f98b4da44d52b0fe9de1c2d0982f1c0556b8
 DIST opera-developer_90.0.4477.0_amd64.deb 87534288 BLAKE2B e2670fc26d8ff72966e0dbae7f80801499f80e5a85874dda603a7617d3e2c11b6cb5f715916fd2037c280b261f41675c5401e0eeab85902a3af382c843a33f00 SHA512 20e545c9f5bd826c9529d8a2545de30e4e8123566429811b64df435b3e441ee88741a800bed889491a073b4431e45159d9893069193413ccc7116ca5f5098073
+DIST opera-developer_91.0.4484.0_amd64.deb 87605720 BLAKE2B 4b7b8f17a0bba21667f1bfe64c05bcf15c0fe20b1bdf928ad806f71f9ce6c8a7d3a8b2318b8b8cc2801a76c7d83172ce20c46514ba26ddd5a401915122dd4e79 SHA512 4056ea6b064867b558e132e70e8ee7c151424a7e8129e2996d8abed12806ee97a56bde613db8c8eff80331e7565bc4b0db10d7e758d24180eda9075d59260fcc
 DIST opera-ffmpeg-codecs-104.0.5083.0.tar.xz 1431840 BLAKE2B 172ba55d6f390eaea644803ddae8c3cee4ee2d585de873db438d43b9e7f6d07f5b0e9b659f06c126f65148148d889948cc3287ee21da00eec08f2e665be47dbc SHA512 9ca7fe8a244b634d65a28602f9e1173694faaab6de95cd0a44aeedc29dffb75b14adf842c69d5ba5631fb40e51f021fce190dc8307148d8e9218230b7cde29b8
diff --git a/www-client/opera-developer/opera-developer-91.0.4484.0.ebuild b/www-client/opera-developer/opera-developer-91.0.4484.0.ebuild
new file mode 100644
index 000000000000..bf2f16f337f7
--- /dev/null
+++ b/www-client/opera-developer/opera-developer-91.0.4484.0.ebuild
@@ -0,0 +1,158 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+CHROMIUM_LANGS="
+	bg bn ca cs da de el en-GB en-US es-419 es fil fi fr hi hr hu id
+	it ja ko lt lv ms nb nl pl pt-BR pt-PT ro ru sk sr sv sw ta te th tr uk vi
+	zh-CN zh-TW
+"
+
+# These are intended for ebuild maintainer use to force RPM if DEB is not available.
+: ${OPERA_FORCE_RPM=no}
+
+inherit chromium-2 pax-utils xdg
+
+if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+	inherit rpm
+	OPERA_ARCHIVE_EXT="rpm"
+else
+	inherit unpacker
+	OPERA_ARCHIVE_EXT="deb"
+fi
+
+DESCRIPTION="A fast and secure web browser"
+HOMEPAGE="https://www.opera.com/"
+LICENSE="OPERA-2018"
+SLOT="0"
+
+SRC_URI_BASE=(
+	"https://download1.operacdn.com/pub/${PN}"
+	"https://download2.operacdn.com/pub/${PN}"
+	"https://download3.operacdn.com/pub/${PN}"
+	"https://download4.operacdn.com/pub/${PN}"
+)
+
+if [[ ${PN} == opera ]]; then
+	MY_PN=${PN}-stable
+	SRC_URI_BASE=( "${SRC_URI_BASE[@]/%//desktop}" )
+else
+	MY_PN=${PN}
+fi
+
+KEYWORDS="-* ~amd64"
+
+FFMPEG_VERSION="104.0.5083.0"
+
+SRC_URI="${SRC_URI_BASE[@]/%//${PV}/linux/${MY_PN}_${PV}_amd64.${OPERA_ARCHIVE_EXT}}
+	proprietary-codecs? (
+		mirror+https://dev.gentoo.org/~sultan/distfiles/www-client/opera/opera-ffmpeg-codecs-${FFMPEG_VERSION}.tar.xz
+	)"
+
+IUSE="+proprietary-codecs suid"
+RESTRICT="bindist mirror strip"
+
+RDEPEND="
+	app-accessibility/at-spi2-atk:2
+	app-accessibility/at-spi2-core:2
+	dev-libs/atk
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	gnome-base/gsettings-desktop-schemas
+	media-libs/alsa-lib
+	media-libs/mesa[gbm(+)]
+	net-misc/curl
+	net-print/cups
+	sys-apps/dbus
+	sys-libs/glibc
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3
+	x11-libs/libdrm
+	x11-libs/libxcb
+	x11-libs/libxkbcommon
+	x11-libs/libxshmfence
+	x11-libs/libX11
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXrandr
+	x11-libs/pango
+"
+
+QA_PREBUILT="*"
+S=${WORKDIR}
+OPERA_HOME="opt/opera${PN#opera}"
+
+pkg_pretend() {
+	# Protect against people using autounmask overzealously
+	use amd64 || die "opera only works on amd64"
+}
+
+pkg_setup() {
+	chromium_suid_sandbox_check_kernel_config
+}
+
+src_unpack() {
+	:
+}
+
+src_install() {
+	dodir /
+	cd "${ED}" || die
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		rpm_src_unpack "${A[0]}"
+	else
+		unpacker
+	fi
+
+	# move to /opt, bug #573052
+	mkdir -p "${OPERA_HOME%${PN}}"
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		mv "usr/lib64/${PN}" "${OPERA_HOME%${PN}}" || die
+	else
+		mv "usr/lib/x86_64-linux-gnu/${PN}" "${OPERA_HOME%${PN}}" || die
+	fi
+	rm -r "usr/lib" || die
+
+	# disable auto update
+	rm "${OPERA_HOME}/${PN%-*}_autoupdate"{,.licenses,.version} || die
+
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		rm "${OPERA_HOME}/setup_repo.sh" || die
+	else
+		rm -r "usr/share/lintian" || die
+
+		# fix docs
+		mv usr/share/doc/${MY_PN} usr/share/doc/${PF} || die
+		gzip -d usr/share/doc/${PF}/changelog.gz || die
+	fi
+
+	# fix desktop file
+	sed -i \
+		-e 's|^TargetEnvironment|X-&|g' \
+		usr/share/applications/${PN}.desktop || die
+
+	# remove unused language packs
+	pushd "${OPERA_HOME}/localization" > /dev/null || die
+	chromium_remove_language_paks
+	popd > /dev/null || die
+
+	# setup opera symlink
+	rm "usr/bin/${PN}" || die
+	dosym "../../${OPERA_HOME}/${PN}" "/usr/bin/${PN}"
+
+	# install proprietary codecs
+	rm "${OPERA_HOME}/resources/ffmpeg_preload_config.json" || die
+	if use proprietary-codecs; then
+		mv lib_extra "${OPERA_HOME}"
+	fi
+
+	# pax mark opera, bug #562038
+	pax-mark m "${OPERA_HOME}/opera"
+	# enable suid sandbox if requested
+	use suid && fperms 4711 "${OPERA_HOME}/opera_sandbox"
+}