www-client/otter: Version bump (bug #605092 by Anton Kochkov).

Package-Manager: Portage-2.3.3, Repoman-2.3.1

1 files changed, 62 insertions, 0 deletions

diff --git a/www-client/otter/otter-0.9.12.ebuild b/www-client/otter/otter-0.9.12.ebuild
new file mode 100644
index 000000000000..dd309e1c77a0
--- /dev/null
+++ b/www-client/otter/otter-0.9.12.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+WANT_CMAKE="always"
+inherit eutils cmake-utils
+
+DESCRIPTION="Project aiming to recreate classic Opera (12.x) UI using Qt5"
+HOMEPAGE="http://otter-browser.org/"
+SRC_URI="https://github.com/Emdek/${PN}/archive/v${PV/_p/-dev}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="spell"
+
+DEPEND="
+	dev-qt/qtconcurrent:5
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtdeclarative:5
+	dev-qt/qtgui:5
+	dev-qt/qtmultimedia:5
+	dev-qt/qtnetwork:5[ssl]
+	dev-qt/qtprintsupport:5
+	dev-qt/qtscript:5
+	dev-qt/qtsql:5
+	dev-qt/qtwebkit:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxmlpatterns:5
+	spell? ( kde-frameworks/sonnet )
+"
+RDEPEND="
+	${DEPEND}
+"
+
+S=${WORKDIR}/${PN}-browser-${PV/_p/-dev}
+DOCS=( CHANGELOG CONTRIBUTING.md TODO )
+
+src_prepare() {
+	if [[ -n ${LINGUAS} ]]; then
+		local lingua
+		for lingua in resources/translations/*.qm; do
+			lingua=$(basename ${lingua})
+			lingua=${lingua/otter-browser_/}
+			lingua=${lingua/.qm/}
+			if ! has ${lingua} ${LINGUAS}; then
+				rm resources/translations/otter-browser_${lingua}.qm || die
+			fi
+		done
+	fi
+
+	if ! use spell; then
+		sed -i -e '/find_package(KF5Sonnet)/d' CMakeLists.txt || die
+	fi
+}
+
+src_install() {
+	cmake-utils_src_install
+	domenu ${PN}-browser.desktop
+}