www-client/opera-beta: automated bump (98.0.4759.1)

Signed-off-by: Mike Gilbert <floppym@gentoo.org>

2 files changed, 166 insertions, 0 deletions

diff --git a/www-client/opera-beta/Manifest b/www-client/opera-beta/Manifest
index ccb7b2f25790..5c46b0924176 100644
--- a/www-client/opera-beta/Manifest
+++ b/www-client/opera-beta/Manifest
@@ -1,5 +1,6 @@
 DIST opera-beta_95.0.4635.10_amd64.deb 101350684 BLAKE2B eb4d2193be0f8e9313adcfde78700213c5bdc0daa9d58fd338b2c1a6657ec2f0a4aef119b008741edbe66f7c560d0008d9d5bb1a12ccd0331b8195fa3a6e7700 SHA512 f3eca403b34f7cfb2b126bd2345b8a8df21d76eb2b3c5a0ab6d5b65ccce22bc76e741c80fc1bad7c1147d4cef5a48b7b1376f4c8f4c0e1daad76c6a6566b7504
 DIST opera-beta_95.0.4635.12_amd64.deb 101346084 BLAKE2B f4e46aaabd3f15c549d3f6865a2ee031fba924c71dd57be78f045323c23c8af8cfe5822b4240b268740a97e6a175539f61f1676c068bda958427cc5f6e3be0ed SHA512 0de16942d4bf5875e436f41fc8d4991290336f754761b8117f54fd8730462107dd91d4e53aae7df711bde4ef6dacd780c372a09fcf024ccf8593721da11143e3
 DIST opera-beta_95.0.4635.15_amd64.deb 101325556 BLAKE2B debdbd0bc69e7e350d2187f145ee701a62e83d3cc130d696ad04d640c5132f2650c806cb7721210e0215c9f584932565c8950305725a7cebf303278c83185bcc SHA512 828552b0f1fe20ad38834af2382ef4a05d790901367ab5967d172d8159b368f8b8ecf47990e724c941ff514c9e9b0dd5887611e03988b60f2c7b779ea9dbf8ac
+DIST opera-beta_98.0.4759.1_amd64.deb 104289216 BLAKE2B b8f228b919600517087786f42326825e5c6149328e124d4fa5ffef72f2cba2827250a5f66f94265dfe511066f5c23954198884b3fd219eda1fb68d927218279c SHA512 33311974079c686e6bcf442428f33f21479b72db657976f591c1602132f849838a1a46aa72c5ba9c6504e590709e7c6eace3464c5c4b5e9d8da40c8b823f68b1
 DIST opera-beta_98.0.4759.3_amd64.deb 104333468 BLAKE2B d661355bf8a96d4f61c10796d164a03fe817bcfa914961e64cff20f8c8f37c283dd29d0106f00db1e50eaae7fdbb549b20778946debeb74802770c398b833bd3 SHA512 97bfd7a7dc32957a61892825280454af0251eb7e6f256b94c1b9cd0c6aecc99da07ae429c4d76752f598824844fbb06ca1dc69fe20a2f3cae85d4ac4a6bf18f8
 DIST opera-ffmpeg-codecs-110.0.5464.2.tar.xz 1280752 BLAKE2B 9f17f85377d06c7c36729ca3a29d02aa2d7fff3bbbeb4cc26f60252e350c50c3a06eeb7e3c896154617ff7ee43d5881177b819618c13dc1254f7d3980bf0c363 SHA512 d9b4a52b29be287e5d20f6922c64e0e3cbfcd7eedd3109c12ff72c376ab14bce4c421be4dccea2ed1e4c899f11dcc8416545911ca84d8d6c994fe6ab87425ff3
diff --git a/www-client/opera-beta/opera-beta-98.0.4759.1.ebuild b/www-client/opera-beta/opera-beta-98.0.4759.1.ebuild
new file mode 100644
index 000000000000..c1bd86836a82
--- /dev/null
+++ b/www-client/opera-beta/opera-beta-98.0.4759.1.ebuild
@@ -0,0 +1,165 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+CHROMIUM_LANGS="
+	bg bn ca cs da de el en-GB en-US es-419 es fil fi fr hi hr hu id
+	it ja ko lt lv ms nb nl pl pt-BR pt-PT ro ru sk sr sv sw ta te th tr uk vi
+	zh-CN zh-TW
+"
+
+# These are intended for ebuild maintainer use to force RPM if DEB is not available.
+: ${OPERA_FORCE_RPM=no}
+
+inherit chromium-2 pax-utils xdg
+
+if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+	inherit rpm
+	OPERA_ARCHIVE_EXT="rpm"
+else
+	inherit unpacker
+	OPERA_ARCHIVE_EXT="deb"
+fi
+
+DESCRIPTION="A fast and secure web browser"
+HOMEPAGE="https://www.opera.com/"
+LICENSE="OPERA-2018"
+SLOT="0"
+
+SRC_URI_BASE=(
+	"https://download1.operacdn.com/pub/${PN}"
+	"https://download2.operacdn.com/pub/${PN}"
+	"https://download3.operacdn.com/pub/${PN}"
+	"https://download4.operacdn.com/pub/${PN}"
+)
+
+if [[ ${PN} == opera ]]; then
+	MY_PN=${PN}-stable
+	SRC_URI_BASE=( "${SRC_URI_BASE[@]/%//desktop}" )
+else
+	MY_PN=${PN}
+fi
+
+KEYWORDS="-* ~amd64"
+
+FFMPEG_VERSION="110.0.5464.2"
+
+SRC_URI="${SRC_URI_BASE[@]/%//${PV}/linux/${MY_PN}_${PV}_amd64.${OPERA_ARCHIVE_EXT}}
+	proprietary-codecs? (
+		mirror+https://dev.gentoo.org/~sultan/distfiles/www-client/opera/opera-ffmpeg-codecs-${FFMPEG_VERSION}.tar.xz
+	)"
+
+IUSE="+proprietary-codecs +suid qt5"
+RESTRICT="bindist mirror strip"
+
+RDEPEND="
+	>=app-accessibility/at-spi2-core-2.46.0:2
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	gnome-base/gsettings-desktop-schemas
+	media-libs/alsa-lib
+	media-libs/mesa[gbm(+)]
+	net-misc/curl
+	net-print/cups
+	sys-apps/dbus
+	sys-libs/glibc
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3
+	x11-libs/libdrm
+	x11-libs/libxcb
+	x11-libs/libxkbcommon
+	x11-libs/libxshmfence
+	x11-libs/libX11
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXrandr
+	x11-libs/pango
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5[X]
+		dev-qt/qtwidgets:5
+	)
+"
+
+QA_PREBUILT="*"
+S=${WORKDIR}
+OPERA_HOME="opt/opera${PN#opera}"
+
+pkg_pretend() {
+	# Protect against people using autounmask overzealously
+	use amd64 || die "opera only works on amd64"
+}
+
+pkg_setup() {
+	chromium_suid_sandbox_check_kernel_config
+}
+
+src_unpack() {
+	:
+}
+
+src_install() {
+	dodir /
+	cd "${ED}" || die
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		rpm_src_unpack "${A[0]}"
+	else
+		unpacker
+	fi
+
+	# move to /opt, bug #573052
+	mkdir -p "${OPERA_HOME%${PN}}"
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		mv "usr/lib64/${PN}" "${OPERA_HOME%${PN}}" || die
+	else
+		mv "usr/lib/x86_64-linux-gnu/${PN}" "${OPERA_HOME%${PN}}" || die
+	fi
+	rm -r "usr/lib" || die
+
+	# disable auto update
+	rm "${OPERA_HOME}/${PN%-*}_autoupdate"{,.licenses,.version} || die
+
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		rm "${OPERA_HOME}/setup_repo.sh" || die
+	else
+		rm -r "usr/share/lintian" || die
+
+		# fix docs
+		mv usr/share/doc/${MY_PN} usr/share/doc/${PF} || die
+		gzip -d usr/share/doc/${PF}/changelog.gz || die
+	fi
+
+	# fix desktop file
+	sed -i \
+		-e 's|^TargetEnvironment|X-&|g' \
+		usr/share/applications/${PN}.desktop || die
+
+	# remove unused language packs
+	pushd "${OPERA_HOME}/localization" > /dev/null || die
+	chromium_remove_language_paks
+	popd > /dev/null || die
+
+	# setup opera symlink
+	rm "usr/bin/${PN}" || die
+	dosym "../../${OPERA_HOME}/${PN}" "/usr/bin/${PN}"
+
+	# install proprietary codecs
+	rm "${OPERA_HOME}/resources/ffmpeg_preload_config.json" || die
+	if use proprietary-codecs; then
+		mv lib_extra "${OPERA_HOME}"
+	fi
+
+	if ! use qt5; then
+		rm "${OPERA_HOME}/libqt5_shim.so" || die
+	fi
+
+	# pax mark opera, bug #562038
+	pax-mark m "${OPERA_HOME}/opera"
+	# enable suid sandbox if requested
+	use suid && fperms 4711 "/${OPERA_HOME}/opera_sandbox"
+}