x11-apps/intel-gpu-tools: version bump to 1.20 #612490

3 files changed, 86 insertions, 0 deletions

diff --git a/x11-apps/intel-gpu-tools/Manifest b/x11-apps/intel-gpu-tools/Manifest
index b00d8c347108..3c5fcdd9c523 100644
--- a/x11-apps/intel-gpu-tools/Manifest
+++ b/x11-apps/intel-gpu-tools/Manifest
@@ -1 +1,2 @@
 DIST intel-gpu-tools-1.15.tar.bz2 1827851 BLAKE2B dac481571603ff36957ad2d5ef89266e744ec39a5623bb2b8e3d2e389d39d7aa09130cd7591e876b02d8edd970fb287c53ea9b520801a4a9ceede294e2917a7f SHA512 407f7c4ce72babbbd3ed08fc77719f88321b56745601b588bb6dce1a659786215e6d1b121af748087746df6f7da1bfd3ae8f9a898173eede5d5bb4a5b24b4559
+DIST intel-gpu-tools-1.20.tar.bz2 2274390 BLAKE2B 55c8614f93f5ed6391d35570ed6e4e36a659bd8ba5d98e321cb1daaf89413a95d1f0911cd07ed00670f0dceacd8f4443894a59b85cce1debeae9f8e01a75f824 SHA512 7b930c6949c04a600792df359f7cd230ca7b843072936c0c674cb9212b2d8c0701c43ef3bebe66b34141ed7a9b39774bbb99466cd52d70b3f1abfe5e52608f25
diff --git a/x11-apps/intel-gpu-tools/intel-gpu-tools-1.20.ebuild b/x11-apps/intel-gpu-tools/intel-gpu-tools-1.20.ebuild
new file mode 100644
index 000000000000..f14f3fa384ae
--- /dev/null
+++ b/x11-apps/intel-gpu-tools/intel-gpu-tools-1.20.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="5"
+
+inherit xorg-2
+
+DESCRIPTION="Intel GPU userland tools"
+
+KEYWORDS="~amd64 ~x86"
+IUSE="alsa glib gsl sound test-programs udev unwind valgrind video_cards_amdgpu video_cards_intel video_cards_nouveau X xrandr xv"
+REQUIRED_USE="test-programs? ( sound? ( alsa gsl ) )"
+RESTRICT="test"
+
+X86_RDEPEND="
+	xv? (
+		x11-libs/libX11
+		x11-libs/libXext
+		x11-libs/libXv
+	)"
+X86_DEPEND=">=x11-proto/dri2proto-2.6"
+RDEPEND="sys-apps/kmod:=
+	sys-process/procps:=
+	>=x11-libs/cairo-1.12.0[X?]
+	>=x11-libs/libdrm-2.4.82[video_cards_amdgpu?,video_cards_intel?,video_cards_nouveau?]
+	>=x11-libs/libpciaccess-0.10
+	alsa? ( media-libs/alsa-lib:= )
+	glib? ( dev-libs/glib:2 )
+	gsl? ( sci-libs/gsl )
+	udev? ( virtual/libudev:= )
+	unwind? ( sys-libs/libunwind )
+	valgrind? ( dev-util/valgrind )
+	video_cards_intel? ( sys-libs/zlib:= )
+	xrandr? ( >=x11-libs/libXrandr-1.3 )
+	amd64? ( ${X86_RDEPEND} )
+	x86? ( ${X86_RDEPEND} )"
+DEPEND="${RDEPEND}
+	amd64? ( ${X86_DEPEND} )
+	x86? ( ${X86_DEPEND} )"
+
+src_configure() {
+	sed -i -E \
+		-e "s:\<alsa=(no|yes):alsa=$(usex alsa):g" \
+		-e "s:\<glib=(no|yes):glib=$(usex glib):g" \
+		-e "s:\<gsl=(no|yes):gsl=$(usex gsl):g" \
+		-e "s:\<udev=(no|yes):udev=$(usex udev):g" \
+		-e "s:\<have_valgrind=(no|yes):have_valgrind=$(usex valgrind):g" \
+		-e "s:\<enable_overlay_xvlib=(no|yes):enable_overlay_xvlib=$(usex xv):g" \
+		configure || die
+	XORG_CONFIGURE_OPTIONS=(
+		$(usex test-programs $(use_enable sound audio) --disable-audio)
+		$(use_enable test-programs tests)
+		$(use_with unwind libunwind)
+		$(use_enable video_cards_amdgpu amdgpu)
+		$(use_enable video_cards_intel intel)
+		$(use_enable video_cards_nouveau nouveau)
+	)
+	xorg-2_src_configure
+}
+
+src_install() {
+	xorg-2_src_install
+	if use test-programs; then
+		local testprogram
+		pushd "${AUTOTOOLS_BUILD_DIR}"/tests >/dev/null || die
+		for testprogram in $(<multi-tests.txt) $(<single-tests.txt); do
+			if [[ -f ${testprogram} ]]; then
+				dobin "${testprogram}"
+			fi
+		done
+		popd >/dev/null
+	fi
+}
+
+pkg_postinst() {
+	xorg-2_pkg_postinst
+	if use test-programs; then
+		elog "Test programs for DRM driver development were installed. These are not"
+		elog "designed to run outside their source tree, so may or may not work as"
+		elog "intended."
+	fi
+}
diff --git a/x11-apps/intel-gpu-tools/metadata.xml b/x11-apps/intel-gpu-tools/metadata.xml
index 49b36752d733..82c48e5a7a21 100644
--- a/x11-apps/intel-gpu-tools/metadata.xml
+++ b/x11-apps/intel-gpu-tools/metadata.xml
@@ -6,7 +6,10 @@
  <name>X11</name>
 </maintainer>
 <use>
+ <flag name="glib">Support reading config files via glib helpers</flag>
  <flag name="test-programs">Install test programs for DRM driver development</flag>
  <flag name="unwind">Provide automatic stack traces on test failures</flag>
+ <flag name="valgrind">Support valgrind annotations</flag>
+ <flag name="xrandr">Enable support for the X RandR extension</flag>
 </use>
 </pkgmetadata>