x11-libs/xapp: add 2.6.1

Signed-off-by: Matthew S. Turnbull <sparky@bluefang-logic.com>
Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 103 insertions, 0 deletions

diff --git a/x11-libs/xapp/Manifest b/x11-libs/xapp/Manifest
index 03b6827e75e9..4e3287c10f32 100644
--- a/x11-libs/xapp/Manifest
+++ b/x11-libs/xapp/Manifest
@@ -1 +1,2 @@
 DIST xapp-2.4.3.tar.gz 252180 BLAKE2B 49ebba445e04205f714fd4a16363674477e1156872ed1d26ac8450c32d688323971301ed97366e36141e91996f64401372dbe5ee4e36130ac4cf70e12e9fcdde SHA512 ecfe97b5a6de6ef06416b3220dc30856c590087c22b77ba2078194995650966e7811a91b3ce6335b363ea5066473d5c59a318232e40a2311341067dcee4719b2
+DIST xapp-2.6.1.tar.gz 270606 BLAKE2B 0f2572b2e9ec4056bea0fc532f5327bd6de4741719a49b68180d45ff00fcea9b760acb362fc39d3f2dc9d94001b7021267a8a84c067aa90c5a201a46be76e97c SHA512 f96006fffac67b312caba644e8da75209c443688b08254b9bb5b17eb9148e66b35a8b1fe336e8880c7b950f8fc696884d8f5d610092c2cb44357ad3bf3ef43c7
diff --git a/x11-libs/xapp/xapp-2.6.1.ebuild b/x11-libs/xapp/xapp-2.6.1.ebuild
new file mode 100644
index 000000000000..36a2b7e8ce5a
--- /dev/null
+++ b/x11-libs/xapp/xapp-2.6.1.ebuild
@@ -0,0 +1,102 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{10..11} )
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome2-utils vala meson python-r1
+
+DESCRIPTION="Cross-desktop libraries and common resources"
+HOMEPAGE="https://github.com/linuxmint/xapp/"
+LICENSE="LGPL-3"
+
+SRC_URI="https://github.com/linuxmint/xapp/archive/${PV}.tar.gz -> ${P}.tar.gz"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+
+SLOT="0"
+IUSE="gtk-doc introspection mate"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	>=dev-libs/glib-2.44.0:2
+	dev-libs/libdbusmenu[gtk3]
+	gnome-base/libgnomekbd:=
+	x11-libs/cairo
+	>=x11-libs/gdk-pixbuf-2.22.0:2[introspection?]
+	>=x11-libs/gtk+-3.16.0:3[introspection?]
+	x11-libs/libxkbfile
+	x11-libs/libX11
+	x11-libs/pango
+
+	mate? (
+		${PYTHON_DEPS}
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+	)
+"
+DEPEND="
+	${RDEPEND}
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	$(vala_depend)
+	dev-python/pygobject:3[${PYTHON_USEDEP}]
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	sys-apps/dbus
+	sys-devel/gettext
+
+	gtk-doc? ( dev-util/gtk-doc )
+"
+
+src_prepare() {
+	vala_src_prepare
+	default
+
+	# don't install distro specific tools
+	sed -i "s/subdir('scripts')/#&/" meson.build || die
+
+	# make mate integrations optional
+	if ! use mate; then
+		sed -i "s/subdir('mate')/#&/" status-applets/meson.build || die
+	fi
+
+	# Fix meson helpers
+	python_setup
+	python_fix_shebang .
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use gtk-doc docs)
+		-Dpy-overrides-dir="/pygobject"
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	# copy pygobject files to each active python target
+	# work-around for "py-overrides-dir" only supporting a single target
+	install_pygobject_override() {
+		PYTHON_GI_OVERRIDESDIR=$("${EPYTHON}" -c 'import gi;print(gi._overridesdir)' || die)
+		einfo "gobject overrides directory: ${PYTHON_GI_OVERRIDESDIR}"
+		mkdir -p "${D}/${PYTHON_GI_OVERRIDESDIR}/" || die
+		cp -r "${D}"/pygobject/* "${D}/${PYTHON_GI_OVERRIDESDIR}/" || die
+		python_optimize "${D}/${PYTHON_GI_OVERRIDESDIR}/"
+	}
+	python_foreach_impl install_pygobject_override
+	rm -r "${D}/pygobject" || die
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+	gnome2_schemas_update
+}