x11-misc/picom: add 11

Update dependencies and sync live ebuild
Drop outdated blocker on x11-misc/compton
Update PYTHON_COMPAT

Closes: https://bugs.gentoo.org/886523
Signed-off-by: Bernard Cafarelli <voyageur@gentoo.org>

3 files changed, 73 insertions, 4 deletions

diff --git a/x11-misc/picom/Manifest b/x11-misc/picom/Manifest
index f0ae8c03d00b..57dca69ae115 100644
--- a/x11-misc/picom/Manifest
+++ b/x11-misc/picom/Manifest
@@ -1 +1,2 @@
 DIST picom-10.2.tar.gz 287166 BLAKE2B feaa07fc5f0a53396675dfd4d8f2507caf6ce355b2db242b25b3559b287845b0505c48194e51c9c7fc6809dd10b871be6adf3e9fc87d91a41f01ccfeb87803ab SHA512 9c0351fbe8a9e76533243c8e76f8e7d10c1e49292f1c8e6c06f31fb0b512542a67970abe803d061c953546ff8d3e704488c263002a5a831f68deb010caee481d
+DIST picom-11.tar.gz 309373 BLAKE2B 1b7a01654fdfde9e3885e54feb36740397e86edb7de490bbc767374928d1581ed2270bdbbf5d5904594ed071bca63e623088483f14e87a9efbd23e8e41a10ef0 SHA512 a0037e838e8a1f02fa4ee6e1b0aac0c9b571ee580d11d44bb49f8591dfea2a1039843da7711b95bf747daac119651736e98cf8e1281297ca1c1f5002a750b7f8
diff --git a/x11-misc/picom/picom-11.ebuild b/x11-misc/picom/picom-11.ebuild
new file mode 100644
index 000000000000..e122ab5870bb
--- /dev/null
+++ b/x11-misc/picom/picom-11.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..12} )
+inherit meson python-any-r1 virtualx xdg
+
+DESCRIPTION="A lightweight compositor for X11 (previously a compton fork)"
+HOMEPAGE="https://github.com/yshui/picom"
+SRC_URI="https://github.com/yshui/picom/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MPL-2.0 MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="+config-file dbus +doc +drm opengl pcre test"
+
+REQUIRED_USE="test? ( dbus )" # avoid "DBus support not compiled in!"
+RESTRICT="test" # but tests require dbus_next
+
+RDEPEND="dev-libs/libev
+	dev-libs/uthash
+	x11-libs/libX11
+	x11-libs/libxcb
+	x11-libs/libXext
+	x11-libs/pixman
+	x11-libs/xcb-util
+	x11-libs/xcb-util-image
+	x11-libs/xcb-util-renderutil
+	config-file? (
+		dev-libs/libconfig:=
+	)
+	dbus? ( sys-apps/dbus )
+	drm? ( x11-libs/libdrm )
+	opengl? ( virtual/opengl )
+	pcre? ( dev-libs/libpcre2:= )"
+DEPEND="${RDEPEND}
+	x11-base/xorg-proto"
+BDEPEND="virtual/pkgconfig
+	doc? ( app-text/asciidoc )
+	test? ( $(python_gen_any_dep 'dev-python/xcffib[${PYTHON_USEDEP}]') )
+"
+
+DOCS=( README.md picom.sample.conf )
+
+python_check_deps() {
+	python_has_version "dev-python/xcffib[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use config-file config_file)
+		$(meson_use dbus)
+		$(meson_use doc with_docs)
+		$(meson_use opengl)
+		$(meson_use pcre regex)
+	)
+
+	meson_src_configure
+}
+
+src_test() {
+	virtx "${S}/tests/run_tests.sh" "${BUILD_DIR}/src/${PN}"
+}
diff --git a/x11-misc/picom/picom-9999.ebuild b/x11-misc/picom/picom-9999.ebuild
index e1b85646fdb2..84c58836cb6e 100644
--- a/x11-misc/picom/picom-9999.ebuild
+++ b/x11-misc/picom/picom-9999.ebuild
@@ -1,9 +1,9 @@
-# Copyright 1999-2023 Gentoo Authors
+# Copyright 1999-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
 
-PYTHON_COMPAT=( python3_{9..11} )
+PYTHON_COMPAT=( python3_{9..12} )
 inherit git-r3 meson python-any-r1 virtualx xdg
 
 DESCRIPTION="A lightweight compositor for X11 (previously a compton fork)"
@@ -23,6 +23,7 @@ RDEPEND="dev-libs/libev
 	x11-libs/libxcb
 	x11-libs/libXext
 	x11-libs/pixman
+	x11-libs/xcb-util
 	x11-libs/xcb-util-image
 	x11-libs/xcb-util-renderutil
 	config-file? (
@@ -31,8 +32,7 @@ RDEPEND="dev-libs/libev
 	dbus? ( sys-apps/dbus )
 	drm? ( x11-libs/libdrm )
 	opengl? ( virtual/opengl )
-	pcre? ( dev-libs/libpcre2:= )
-	!x11-misc/compton"
+	pcre? ( dev-libs/libpcre2:= )"
 DEPEND="${RDEPEND}
 	x11-base/xorg-proto"
 BDEPEND="virtual/pkgconfig