summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
-rw-r--r--app-arch/dump/dump-0.4.47-r2.ebuild96
-rw-r--r--dev-python/cwcwidth/cwcwidth-0.1.8.ebuild2
-rw-r--r--dev-python/pyte/pyte-0.8.1.ebuild2
-rw-r--r--dev-python/repoze-lru/metadata.xml1
-rw-r--r--dev-python/repoze-lru/repoze-lru-0.7-r3.ebuild2
-rw-r--r--dev-python/routes/metadata.xml1
-rw-r--r--dev-python/tasklib/tasklib-2.5.1.ebuild2
-rw-r--r--dev-util/rbtools/rbtools-4.0-r2.ebuild59
-rw-r--r--eclass/eapi8-dosym.eclass4
-rw-r--r--media-gfx/termtosvg/termtosvg-1.1.0-r1.ebuild2
10 files changed, 164 insertions, 7 deletions
diff --git a/app-arch/dump/dump-0.4.47-r2.ebuild b/app-arch/dump/dump-0.4.47-r2.ebuild
new file mode 100644
index 000000000000..11b1136eccae
--- /dev/null
+++ b/app-arch/dump/dump-0.4.47-r2.ebuild
@@ -0,0 +1,96 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit readme.gentoo-r1
+
+MY_P="${PN}-$(ver_rs 2 b)"
+
+DESCRIPTION="Dump/restore ext2fs backup utilities"
+HOMEPAGE="https://dump.sourceforge.io/"
+SRC_URI="mirror://sourceforge/dump/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+# We keep uuid USE flag default dsiabled for this version. Don't forget
+# to default enable it for later versions as this is the upstream default.
+IUSE="bzip2 debug ermt lzo readline selinux sqlite ssl static test uuid zlib"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="
+ ermt? ( ssl )
+ ssl? ( zlib )
+ test? ( sqlite? ( uuid ) )"
+
+RDEPEND="
+ >=sys-fs/e2fsprogs-1.27:=
+ sys-apps/util-linux
+ bzip2? (
+ app-arch/bzip2:=
+ static? ( app-arch/bzip2[static-libs] )
+ )
+ zlib? ( >=sys-libs/zlib-1.1.4:= )
+ lzo? (
+ dev-libs/lzo:2=
+ static? ( dev-libs/lzo:2[static-libs] )
+ )
+ sqlite? ( dev-db/sqlite:3= )
+ ermt? ( dev-libs/openssl:0= )
+ ssl? ( dev-libs/openssl:0= )
+ readline? (
+ sys-libs/readline:0=
+ sys-libs/ncurses:=
+ static? ( sys-libs/ncurses:=[static-libs] )
+ )"
+DEPEND="${RDEPEND}
+ virtual/os-headers"
+BDEPEND="virtual/pkgconfig"
+
+src_configure() {
+ local myeconfargs=(
+ --with-dumpdatespath=/etc/dumpdates
+ --with-rmtpath='$(sbindir)/rmt'
+ --enable-blkid
+ $(use_enable bzip2)
+ $(use_enable debug)
+ $(use_enable ermt)
+ $(use_enable lzo)
+ $(use_enable readline)
+ $(use_enable selinux)
+ $(use_enable sqlite)
+ $(use_enable ssl)
+ $(use_enable static static-progs)
+ $(use_enable uuid)
+ $(use_enable zlib)
+ )
+ econf "${myeconfargs[@]}"
+}
+
+src_install() {
+ default
+
+ mv "${ED}"/usr/sbin/{,dump-}rmt || die
+ mv "${ED}"/usr/share/man/man8/{,dump-}rmt.8 || die
+ use ermt && newsbin rmt/ermt dump-ermt
+
+ dodoc KNOWNBUGS MAINTAINERS REPORTING-BUGS
+ dodoc -r examples
+
+ # Don't install pre-compressed files
+ gunzip "${ED}"/usr/share/doc/${PF}/examples/cron_dump_to_disk/backupskel.tar.gz \
+ || die
+
+ local DOC_CONTENTS="dump has serious bugs
+ (see https://sourceforge.net/p/dump/bugs/162/ and
+ https://sourceforge.net/p/dump/bugs/174/). This tool should only
+ be used for restoring old backups, not for creating new ones.
+ \n\n${CATEGORY}/${PN} installs 'rmt' as 'dump-rmt'.
+ This is to avoid conflicts with app-arch/tar 'rmt'."
+ readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+ readme.gentoo_print_elog
+}
diff --git a/dev-python/cwcwidth/cwcwidth-0.1.8.ebuild b/dev-python/cwcwidth/cwcwidth-0.1.8.ebuild
index 499eb824bf65..92afc0c794b0 100644
--- a/dev-python/cwcwidth/cwcwidth-0.1.8.ebuild
+++ b/dev-python/cwcwidth/cwcwidth-0.1.8.ebuild
@@ -5,7 +5,7 @@ EAPI=8
DISTUTILS_EXT=1
DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{9..11} )
+PYTHON_COMPAT=( python3_{10..12} )
inherit distutils-r1
diff --git a/dev-python/pyte/pyte-0.8.1.ebuild b/dev-python/pyte/pyte-0.8.1.ebuild
index 4bdc7253de01..c0833815cff7 100644
--- a/dev-python/pyte/pyte-0.8.1.ebuild
+++ b/dev-python/pyte/pyte-0.8.1.ebuild
@@ -4,7 +4,7 @@
EAPI=8
DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{9..11} )
+PYTHON_COMPAT=( python3_{10..12} )
inherit distutils-r1
diff --git a/dev-python/repoze-lru/metadata.xml b/dev-python/repoze-lru/metadata.xml
index 8f4b70bfc235..ba8fd2e54a87 100644
--- a/dev-python/repoze-lru/metadata.xml
+++ b/dev-python/repoze-lru/metadata.xml
@@ -7,5 +7,6 @@
</maintainer>
<upstream>
<remote-id type="pypi">repoze.lru</remote-id>
+ <remote-id type="github">repoze/repoze.lru</remote-id>
</upstream>
</pkgmetadata>
diff --git a/dev-python/repoze-lru/repoze-lru-0.7-r3.ebuild b/dev-python/repoze-lru/repoze-lru-0.7-r3.ebuild
index 02ba6f7206c7..9a0ee04c9318 100644
--- a/dev-python/repoze-lru/repoze-lru-0.7-r3.ebuild
+++ b/dev-python/repoze-lru/repoze-lru-0.7-r3.ebuild
@@ -4,7 +4,7 @@
EAPI=8
DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{9..11} pypy3 )
+PYTHON_COMPAT=( python3_{10..12} pypy3 )
inherit distutils-r1
diff --git a/dev-python/routes/metadata.xml b/dev-python/routes/metadata.xml
index a2282f1b20d6..ee4979d961fd 100644
--- a/dev-python/routes/metadata.xml
+++ b/dev-python/routes/metadata.xml
@@ -8,5 +8,6 @@
<stabilize-allarches/>
<upstream>
<remote-id type="pypi">Routes</remote-id>
+ <remote-id type="github">bbangert/routes</remote-id>
</upstream>
</pkgmetadata>
diff --git a/dev-python/tasklib/tasklib-2.5.1.ebuild b/dev-python/tasklib/tasklib-2.5.1.ebuild
index 405a37e4b487..d561abe64e6c 100644
--- a/dev-python/tasklib/tasklib-2.5.1.ebuild
+++ b/dev-python/tasklib/tasklib-2.5.1.ebuild
@@ -4,7 +4,7 @@
EAPI=8
DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{9..11} )
+PYTHON_COMPAT=( python3_{10..12} )
inherit distutils-r1 pypi
diff --git a/dev-util/rbtools/rbtools-4.0-r2.ebuild b/dev-util/rbtools/rbtools-4.0-r2.ebuild
new file mode 100644
index 000000000000..47594aae9c17
--- /dev/null
+++ b/dev-util/rbtools/rbtools-4.0-r2.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1
+
+MY_PN="RBTools"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Command line tools for use with Review Board"
+HOMEPAGE="https://www.reviewboard.org/"
+SRC_URI="https://downloads.reviewboard.org/releases/${MY_PN}/$(ver_cut 1-2)/${MY_P}.tar.gz"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+RDEPEND="
+ >=dev-python/importlib-metadata-4.12[${PYTHON_USEDEP}]
+ dev-python/colorama[${PYTHON_USEDEP}]
+ >=dev-python/pydiffx-1.1[${PYTHON_USEDEP}]
+ =dev-python/pydiffx-1.1*[${PYTHON_USEDEP}]
+ >=dev-python/six-1.8.0[${PYTHON_USEDEP}]
+ dev-python/texttable[${PYTHON_USEDEP}]
+ >=dev-python/typing-extensions-4.3.0[${PYTHON_USEDEP}]
+ dev-python/tqdm[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ dev-python/setuptools[${PYTHON_USEDEP}]
+ test? (
+ >=dev-python/kgb-6.1[${PYTHON_USEDEP}]
+ dev-python/pytest-env[${PYTHON_USEDEP}]
+ dev-vcs/git
+ dev-vcs/mercurial
+ )
+"
+
+DOCS=( AUTHORS NEWS README.md )
+
+distutils_enable_tests pytest
+
+src_prepare() {
+ default
+
+ # Avoid tests requiring unpackaged test data
+ rm -f rbtools/clients/tests/test_scanning.py || die
+
+ # Avoid repository specific tests to avoid dependencies on them
+ rm -f rbtools/clients/tests/test_{cvs,git,mercurial,svn}.py || die
+
+ # Fix test that appears to expect case-insentive comparison
+ sed -i -e 's/TEST CONTENT/Test content/' rbtools/utils/tests/test_console.py || die
+}
diff --git a/eclass/eapi8-dosym.eclass b/eclass/eapi8-dosym.eclass
index 4e3977ef54cf..93b11dda7fd6 100644
--- a/eclass/eapi8-dosym.eclass
+++ b/eclass/eapi8-dosym.eclass
@@ -31,7 +31,7 @@ esac
_dosym8_canonicalize() {
local path slash i prev out IFS=/
- path=( $1 )
+ read -r -d '' -a path <<< "$1"
[[ $1 == /* ]] && slash=/
while true; do
@@ -39,7 +39,7 @@ _dosym8_canonicalize() {
# or as a special case, "/.." at the beginning of the path.
# Also drop empty and "." path components as we go along.
prev=
- for i in ${!path[@]}; do
+ for i in "${!path[@]}"; do
if [[ -z ${path[i]} || ${path[i]} == . ]]; then
unset "path[i]"
elif [[ ${path[i]} != .. ]]; then
diff --git a/media-gfx/termtosvg/termtosvg-1.1.0-r1.ebuild b/media-gfx/termtosvg/termtosvg-1.1.0-r1.ebuild
index 57ddbbfdd0e0..c9922d7c383a 100644
--- a/media-gfx/termtosvg/termtosvg-1.1.0-r1.ebuild
+++ b/media-gfx/termtosvg/termtosvg-1.1.0-r1.ebuild
@@ -4,7 +4,7 @@
EAPI=8
DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{9..11} )
+PYTHON_COMPAT=( python3_{10..12} )
inherit distutils-r1