1 files changed, 0 insertions, 66 deletions
diff --git a/app-admin/awscli/awscli-1.22.99.ebuild b/app-admin/awscli/awscli-1.22.99.ebuild
deleted file mode 100644
index 2040c8cb81d2..000000000000
--- a/app-admin/awscli/awscli-1.22.99.ebuild
+++ /dev/null
@@ -1,66 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{8..10} )
-
-inherit bash-completion-r1 distutils-r1 multiprocessing
-
-DESCRIPTION="Universal Command Line Environment for AWS"
-HOMEPAGE="https://pypi.org/project/awscli/"
-#SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz"
-SRC_URI="https://github.com/aws/aws-cli/archive/${PV}.tar.gz -> ${P}.tar.gz"
-S="${WORKDIR}/aws-cli-${PV}"
-
-LICENSE="Apache-2.0"
-SLOT="0"
-KEYWORDS="~amd64 ~arm64 ~x86"
-
-# awscli 1.22.55 → botocore 1.24.0
-# so botocore is x.(y+2).(z-55)
-BOTOCORE_PV="$(ver_cut 1).$(( $(ver_cut 2) + 2)).$(( $(ver_cut 3-) - 55))"
-RDEPEND="
-	>=dev-python/botocore-${BOTOCORE_PV}[${PYTHON_USEDEP}]
-	dev-python/colorama[${PYTHON_USEDEP}]
-	dev-python/docutils[${PYTHON_USEDEP}]
-	dev-python/rsa[${PYTHON_USEDEP}]
-	>=dev-python/s3transfer-0.4.0[${PYTHON_USEDEP}]
-	dev-python/pyyaml[${PYTHON_USEDEP}]
-"
-BDEPEND="
-	test? (
-		dev-python/pytest-xdist[${PYTHON_USEDEP}]
-	)
-"
-
-distutils_enable_tests pytest
-
-src_prepare() {
-	# do not rely on bundled deps in botocore (sic!)
-	find -name '*.py' -exec sed -i \
-		-e 's:from botocore[.]vendored import:import:' \
-		-e 's:from botocore[.]vendored[.]:from :' \
-		{} + || die
-	# strip overzealous upper bounds on requirements
-	sed -i -e 's:,<[0-9.]*::' -e 's:==:>=:' setup.py || die
-	distutils-r1_src_prepare
-}
-
-python_test() {
-	# integration tests require AWS credentials and Internet access
-	epytest tests/{functional,unit} \
-		-n "$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")"
-}
-
-python_install_all() {
-	newbashcomp bin/aws_bash_completer aws
-
-	insinto /usr/share/zsh/site-functions
-	newins bin/aws_zsh_completer.sh _aws
-
-	distutils-r1_python_install_all
-
-	rm "${ED}"/usr/bin/{aws.cmd,aws_bash_completer,aws_zsh_completer.sh} || die
-}