1 files changed, 91 insertions, 0 deletions
diff --git a/app-arch/file-roller/file-roller-3.26.2.ebuild b/app-arch/file-roller/file-roller-3.26.2.ebuild
new file mode 100644
index 000000000000..b7717363afee
--- /dev/null
+++ b/app-arch/file-roller/file-roller-3.26.2.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+
+inherit gnome2 readme.gentoo-r1
+
+DESCRIPTION="Archive manager for GNOME"
+HOMEPAGE="https://wiki.gnome.org/Apps/FileRoller"
+
+LICENSE="GPL-2+ CC-BY-SA-3.0"
+SLOT="0"
+IUSE="libnotify nautilus packagekit"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
+
+# gdk-pixbuf used extensively in the source
+# cairo used in eggtreemultidnd.c
+# pango used in fr-window
+RDEPEND="
+	>=app-arch/libarchive-3:=
+	>=dev-libs/glib-2.36:2
+	>=dev-libs/json-glib-0.14
+	>=x11-libs/gtk+-3.13.2:3
+	sys-apps/file
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	x11-libs/pango
+	libnotify? ( >=x11-libs/libnotify-0.4.3:= )
+	nautilus? ( >=gnome-base/nautilus-2.22.2 )
+	packagekit? ( app-admin/packagekit-base )
+"
+# libxml2 required for glib-compile-resources
+DEPEND="${RDEPEND}
+	dev-libs/libxml2:2
+	>=dev-util/intltool-0.50.1
+	dev-util/itstool
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+# eautoreconf needs:
+#	gnome-base/gnome-common
+
+DISABLE_AUTOFORMATTING="yes"
+DOC_CONTENTS="
+${PN} is a frontend for several archiving utilities. If you want a
+particular archive format support, see ${HOMEPAGE}
+and install the relevant package. For example:
+7-zip   - app-arch/p7zip
+ace     - app-arch/unace
+arj     - app-arch/arj
+cpio    - app-arch/cpio
+deb     - app-arch/dpkg
+iso     - app-cdr/cdrtools
+jar,zip - app-arch/zip and app-arch/unzip
+lha     - app-arch/lha
+lzop    - app-arch/lzop
+lz4     - app-arch/lz4
+rar     - app-arch/unrar or app-arch/unar
+rpm     - app-arch/rpm
+unstuff - app-arch/stuffit
+zoo     - app-arch/zoo"
+
+src_prepare() {
+	# File providing Gentoo package names for various archivers
+	cp -v "${FILESDIR}"/3.22-packages.match data/packages.match || die
+	gnome2_src_prepare
+}
+
+src_configure() {
+	# --disable-debug because enabling it adds -O0 to CFLAGS
+	gnome2_src_configure \
+		--disable-run-in-place \
+		--disable-static \
+		--disable-debug \
+		--enable-magic \
+		--enable-libarchive \
+		$(use_enable libnotify notification) \
+		$(use_enable nautilus nautilus-actions) \
+		$(use_enable packagekit)
+}
+
+src_install() {
+	gnome2_src_install
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+	readme.gentoo_print_elog
+}