1 files changed, 41 insertions, 0 deletions
diff --git a/app-arch/gzip/gzip-1.6.ebuild b/app-arch/gzip/gzip-1.6.ebuild
new file mode 100644
index 000000000000..e3619f210d2d
--- /dev/null
+++ b/app-arch/gzip/gzip-1.6.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="4"
+
+inherit eutils flag-o-matic
+
+DESCRIPTION="Standard GNU compressor"
+HOMEPAGE="http://www.gnu.org/software/gzip/"
+SRC_URI="mirror://gnu-alpha/gzip/${P}.tar.xz
+	mirror://gnu/gzip/${P}.tar.xz
+	mirror://gentoo/${P}.tar.xz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="alpha amd64 arm arm64 hppa ia64 m68k ~mips ppc ppc64 s390 sh sparc x86 ~ppc-aix ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~hppa-hpux ~ia64-hpux ~x86-interix ~amd64-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="pic static"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-1.3.8-install-symlinks.patch
+	epatch "${FILESDIR}"/${PN}-1.4-asmv.patch
+}
+
+src_configure() {
+	use static && append-flags -static
+	# avoid text relocation in gzip
+	use pic && export DEFS="NO_ASM"
+	econf
+}
+
+src_install() {
+	default
+	docinto txt
+	dodoc algorithm.doc gzip.doc
+
+	# keep most things in /usr, just the fun stuff in /
+	dodir /bin
+	mv "${ED}"/usr/bin/{gunzip,gzip,uncompress,zcat} "${ED}"/bin/ || die
+	sed -e "s:${EPREFIX}/usr:${EPREFIX}:" -i "${ED}"/bin/gunzip || die
+}