1 files changed, 0 insertions, 88 deletions
diff --git a/app-misc/tmux/tmux-2.9.ebuild b/app-misc/tmux/tmux-2.9.ebuild
deleted file mode 100644
index 636f5f18de21..000000000000
--- a/app-misc/tmux/tmux-2.9.ebuild
+++ /dev/null
@@ -1,88 +0,0 @@
-# Copyright 1999-2019 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-inherit autotools flag-o-matic
-
-DESCRIPTION="Terminal multiplexer"
-HOMEPAGE="https://tmux.github.io/"
-if [[ "${PV}" == 9999 ]] ; then
-	inherit git-r3
-	SRC_URI="https://raw.githubusercontent.com/przepompownia/tmux-bash-completion/678a27616b70c649c6701cae9cd8c92b58cc051b/completions/tmux -> tmux-bash-completion-678a27616b70c649c6701cae9cd8c92b58cc051b"
-	EGIT_REPO_URI="https://github.com/tmux/tmux.git"
-else
-	SRC_URI="https://github.com/tmux/tmux/releases/download/$(ver_cut 1-2)/${P/_/-}.tar.gz"
-	[[ "${PV}" == *_rc* ]] || \
-	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
-	S="${WORKDIR}/${P/_/-}"
-fi
-
-LICENSE="ISC"
-SLOT="0"
-IUSE="debug selinux utempter vim-syntax kernel_FreeBSD kernel_linux"
-
-DEPEND="
-	dev-libs/libevent:0=
-	sys-libs/ncurses:0=
-	utempter? (
-		kernel_linux? ( sys-libs/libutempter )
-		kernel_FreeBSD? ( || ( >=sys-freebsd/freebsd-lib-9.0 sys-libs/libutempter ) )
-	)"
-
-BDEPEND="
-	virtual/pkgconfig"
-
-RDEPEND="
-	${DEPEND}
-	selinux? ( sec-policy/selinux-screen )
-	vim-syntax? ( app-vim/vim-tmux )"
-
-DOCS=( CHANGES README TODO )
-
-PATCHES=(
-	"${FILESDIR}/${PN}-2.4-flags.patch"
-
-	# upstream fixes (can be removed with next version bump)
-)
-
-src_prepare() {
-	# bug 438558
-	# 1.7 segfaults when entering copy mode if compiled with -Os
-	replace-flags -Os -O2
-
-	default
-	eautoreconf
-}
-
-src_configure() {
-	local myeconfargs=(
-		--sysconfdir="${EPREFIX}"/etc
-		$(use_enable debug)
-		$(use_enable utempter)
-	)
-	econf "${myeconfargs[@]}"
-}
-
-src_install() {
-	default
-
-	einstalldocs
-
-	dodoc example_tmux.conf
-	docompress -x /usr/share/doc/${PF}/example_tmux.conf
-}
-
-pkg_postinst() {
-	if ! ver_test 1.9a -ge ${REPLACING_VERSIONS:-1.9a}; then
-		echo
-		ewarn "Some configuration options changed in this release."
-		ewarn "Please read the CHANGES file in /usr/share/doc/${PF}/"
-		ewarn
-		ewarn "WARNING: After updating to ${P} you will _not_ be able to connect to any"
-		ewarn "older, running tmux server instances. You'll have to use an existing client to"
-		ewarn "end your old sessions or kill the old server instances. Otherwise you'll have"
-		ewarn "to temporarily downgrade to access them."
-		echo
-	fi
-}