1 files changed, 53 insertions, 0 deletions
diff --git a/dev-python/backports-functools-lru-cache/backports-functools-lru-cache-1.5.ebuild b/dev-python/backports-functools-lru-cache/backports-functools-lru-cache-1.5.ebuild
new file mode 100644
index 000000000000..237ca59d9de4
--- /dev/null
+++ b/dev-python/backports-functools-lru-cache/backports-functools-lru-cache-1.5.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 pypy )
+
+inherit distutils-r1
+
+MY_PN="${PN/-/.}"
+MY_PN="${MY_PN//-/_}"
+DESCRIPTION="Backport of functools.lru_cache from Python 3.3"
+HOMEPAGE="https://github.com/jaraco/backports.functools_lru_cache"
+SRC_URI="mirror://pypi/${PN:0:1}/${MY_PN}/${MY_PN}-${PV}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos ~x86-macos"
+IUSE="doc test"
+
+RDEPEND="dev-python/backports[${PYTHON_USEDEP}]"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/setuptools_scm-1.15.0[${PYTHON_USEDEP}]
+	doc? (
+		>=dev-python/jaraco-packaging-3.2[${PYTHON_USEDEP}]
+		dev-python/rst-linker[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+	)
+	test? (
+		>=dev-python/pytest-2.8[${PYTHON_USEDEP}]
+	)
+"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+python_compile_all() {
+	if use doc; then
+		cd docs || die
+		sphinx-build . _build/html || die
+		HTML_DOCS=( docs/_build/html/. )
+	fi
+}
+
+python_test() {
+	PYTHONPATH=. py.test || die "tests failed with ${EPYTHON}"
+}
+
+python_install() {
+	# avoid a collision with dev-python/backports
+	rm "${BUILD_DIR}"/lib/backports/__init__.py || die
+	distutils-r1_python_install --skip-build
+}