1 files changed, 43 insertions, 0 deletions
diff --git a/dev-python/backports-tempfile/backports-tempfile-1.0-r1.ebuild b/dev-python/backports-tempfile/backports-tempfile-1.0-r1.ebuild
new file mode 100644
index 000000000000..f96bb176e088
--- /dev/null
+++ b/dev-python/backports-tempfile/backports-tempfile-1.0-r1.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit distutils-r1
+
+MY_PN=${PN/-/.}
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="Backport of new features in Python's tempfile module"
+HOMEPAGE="https://github.com/PiDelport/backports.tempfile https://pypi.org/project/backports.tempfile/"
+SRC_URI="mirror://pypi/${P:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="PSF-2.3"
+SLOT="0"
+KEYWORDS="amd64 ~arm ~arm64 x86 ~amd64-linux ~x86-linux"
+IUSE=""
+RDEPEND="
+	dev-python/backports-weakref[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]"
+# Tests require backports.test.support
+RESTRICT="test"
+S="${WORKDIR}/${MY_P}"
+
+python_prepare_all() {
+	sed -e "s|'setuptools_scm'||" \
+		-i setup.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	PYTHONPATH="${BUILD_DIR}/lib" \
+		"${PYTHON:-python}" tests/test_tempfile.py || die "tests failed with ${EPYTHON}"
+}
+
+python_install() {
+	# avoid collisions due to namespaces
+	rm "${BUILD_DIR}"/lib/backports/__init__.py || die
+	distutils-r1_python_install --skip-build
+}