1 files changed, 56 insertions, 0 deletions
diff --git a/dev-python/pipdeptree/pipdeptree-2.23.4.ebuild b/dev-python/pipdeptree/pipdeptree-2.23.4.ebuild
new file mode 100644
index 000000000000..21df3b3c44a7
--- /dev/null
+++ b/dev-python/pipdeptree/pipdeptree-2.23.4.ebuild
@@ -0,0 +1,56 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( pypy3 python3_{10..13} )
+
+inherit distutils-r1 pypi optfeature
+
+DESCRIPTION="Utility for displaying installed packages in a dependency tree"
+HOMEPAGE="
+	https://github.com/tox-dev/pipdeptree/
+	https://pypi.org/project/pipdeptree/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="amd64 ~arm64 ~riscv"
+
+RDEPEND="
+	>=dev-python/packaging-23.1[${PYTHON_USEDEP}]
+	>=dev-python/pip-23.1.2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/hatch-vcs[${PYTHON_USEDEP}]
+	test? (
+		dev-python/graphviz[${PYTHON_USEDEP}]
+		>=dev-python/pytest-console-scripts-1.4.1[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/virtualenv[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# upstream lower bounds are meaningless
+	sed -i -e 's:>=[0-9.]*::' pyproject.toml || die
+
+	find -name '*.py' -exec \
+		sed -i -e 's:pip[.]_vendor[.]::' {} + || die
+}
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -p pytest_mock -p console-scripts
+}
+
+pkg_postinst() {
+	optfeature \
+		"visualising the dependency graph with --graph-output" \
+		dev-python/graphviz
+}