1 files changed, 0 insertions, 88 deletions
diff --git a/games-fps/gzdoom/gzdoom-4.3.1.ebuild b/games-fps/gzdoom/gzdoom-4.3.1.ebuild
deleted file mode 100644
index 1ba984d753b4..000000000000
--- a/games-fps/gzdoom/gzdoom-4.3.1.ebuild
+++ /dev/null
@@ -1,88 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-inherit cmake desktop xdg
-
-DESCRIPTION="A modder-friendly OpenGL source port based on the DOOM engine"
-HOMEPAGE="https://zdoom.org"
-SRC_URI="https://github.com/coelckers/${PN}/archive/g${PV}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="BSD BZIP2 DUMB-0.9.3 GPL-3 LGPL-3 MIT
-	non-free? ( Activision ChexQuest3 DOOM-COLLECTORS-EDITION freedist )"
-SLOT="0"
-KEYWORDS="~amd64 ~arm ~x86"
-IUSE="alsa fluidsynth gtk gtk2 mpg123 +non-free openmp sndfile"
-
-DEPEND="
-	media-libs/libsdl2[opengl]
-	media-libs/openal
-	sys-libs/zlib
-	virtual/jpeg:0
-	alsa? ( media-libs/alsa-lib )
-	fluidsynth? ( media-sound/fluidsynth:= )
-	gtk? (
-		gtk2? ( x11-libs/gtk+:2 )
-		!gtk2? ( x11-libs/gtk+:3 )
-	)
-	mpg123? ( media-sound/mpg123 )
-	sndfile? ( media-libs/libsndfile )"
-RDEPEND="${DEPEND}"
-
-S="${WORKDIR}/${PN}-g${PV}"
-
-PATCHES=(
-	"${FILESDIR}/${PN}-4.2.1-install_soundfonts.patch"
-	"${FILESDIR}/${PN}-4.2.1-Introduce-the-BUILD_NONFREE-option.patch"
-)
-
-src_prepare() {
-	rm -rf docs/licenses || die
-	if ! use non-free ; then
-		rm -rf wadsrc_bm wadsrc_extra || die
-	fi
-
-	cmake_src_prepare
-}
-
-src_configure() {
-	local mycmakeargs=(
-		-DINSTALL_DOCS_PATH="${EPREFIX}/usr/share/doc/${PF}"
-		-DINSTALL_PK3_PATH="${EPREFIX}/usr/share/doom"
-		-DINSTALL_SOUNDFONT_PATH="${EPREFIX}/usr/share/doom"
-		-DDYN_FLUIDSYNTH=OFF
-		-DDYN_OPENAL=OFF
-		-DDYN_SNDFILE=OFF
-		-DDYN_MPG123=OFF
-		-DNO_GTK="$(usex !gtk)"
-		-DNO_OPENAL=OFF
-		-DNO_OPENMP="$(usex !openmp)"
-		-DBUILD_NONFREE="$(usex non-free)"
-		-DCMAKE_DISABLE_FIND_PACKAGE_ALSA="$(usex !alsa)"
-		-DCMAKE_DISABLE_FIND_PACKAGE_FluidSynth="$(usex !fluidsynth)"
-		-DCMAKE_DISABLE_FIND_PACKAGE_MPG123="$(usex !mpg123)"
-		-DCMAKE_DISABLE_FIND_PACKAGE_SndFile="$(usex !sndfile)"
-	)
-	cmake_src_configure
-}
-
-src_install() {
-	newicon src/posix/zdoom.xpm "${PN}.xpm"
-	make_desktop_entry "${PN}" "GZDoom" "${PN}" "Game;ActionGame"
-	cmake_src_install
-}
-
-pkg_postinst() {
-	xdg_pkg_postinst
-
-	if ! use non-free ; then
-		ewarn
-		ewarn "GZDoom installed without non-free components."
-		ewarn "Note: The non-free game_support.pk3 file is needed to play"
-		ewarn "      games natively supported by GZDoom."
-		ewarn "A list of games natively supported by GZDoom is available"
-		ewarn "on the ZDoom wiki: https://zdoom.org/wiki/IWAD"
-		ewarn
-	fi
-}