1 files changed, 60 insertions, 0 deletions
diff --git a/lxqt-base/lxqt-session/lxqt-session-0.13.0.ebuild b/lxqt-base/lxqt-session/lxqt-session-0.13.0.ebuild
new file mode 100644
index 000000000000..7baa835721a7
--- /dev/null
+++ b/lxqt-base/lxqt-session/lxqt-session-0.13.0.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils eapi7-ver
+
+DESCRIPTION="LXQT session manager"
+HOMEPAGE="https://lxqt.org/"
+
+MY_PV="$(ver_cut 1-2)*"
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/lxqt/${PN}.git"
+else
+	SRC_URI="https://downloads.lxqt.org/downloads/${PN}/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+fi
+
+IUSE="+themes +udev"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+
+RDEPEND="
+	>=dev-libs/libqtxdg-3.0.0
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	kde-frameworks/kwindowsystem:5[X]
+	=lxqt-base/liblxqt-${MY_PV}
+	x11-libs/libX11
+	x11-misc/xdg-user-dirs
+	themes? ( =x11-themes/lxqt-themes-${MY_PV} )
+	udev? ( virtual/libudev )
+	!lxqt-base/lxqt-common
+"
+DEPEND="${RDEPEND}
+	dev-qt/linguist-tools:5
+	>=dev-util/lxqt-build-tools-0.5.0
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_LIBUDEV=$(usex udev)
+		-DPULL_TRANSLATIONS=OFF
+	)
+	cmake-utils_src_configure
+}
+
+src_install(){
+	cmake-utils_src_install
+	doman lxqt-config-session/man/*.1 lxqt-session/man/*.1
+
+	echo XDG_CONFIG_DIRS=\"${EPREFIX}/usr/share\" >> 91lxqt-config-dir
+	doenvd 91lxqt-config-dir
+}