1 files changed, 57 insertions, 0 deletions
diff --git a/media-video/vcdimager/vcdimager-2.0.1.ebuild b/media-video/vcdimager/vcdimager-2.0.1.ebuild
new file mode 100644
index 000000000000..618eb4d7ef3c
--- /dev/null
+++ b/media-video/vcdimager/vcdimager-2.0.1.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit multilib-minimal
+
+DESCRIPTION="GNU VCDimager"
+HOMEPAGE="https://www.gnu.org/software/vcdimager/"
+SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd"
+IUSE="static-libs +xml"
+
+RDEPEND="
+	>=dev-libs/libcdio-2.0.0:0=[-minimal,${MULTILIB_USEDEP}]
+	dev-libs/popt
+	xml? ( dev-libs/libxml2:2 )
+"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+"
+
+DOCS=( AUTHORS BUGS ChangeLog FAQ HACKING NEWS README THANKS TODO )
+
+src_prepare() {
+	default
+
+	# Avoid building useless programs. Bug #226249
+	sed -i \
+		-e 's/check_PROGRAMS =/check_PROGRAMS +=/' \
+		-e 's/noinst_PROGRAMS =/check_PROGRAMS =/' \
+		test/Makefile.in || die
+	sed -i \
+		-e 's/noinst_PROGRAMS =/check_PROGRAMS =/' \
+		example/Makefile.in || die
+}
+
+multilib_src_configure() {
+	local myeconfargs=(
+		$(use_enable static-libs static)
+	)
+	multilib_is_native_abi || myeconfargs+=( --without-cli-frontend )
+	if ! use xml || ! multilib_is_native_abi ; then
+		myeconfargs+=( --without-xml-frontend )
+	fi
+
+	ECONF_SOURCE="${S}" \
+		econf ${myeconfargs[@]}
+}
+
+multilib_src_install_all() {
+	find "${D}" -name '*.la' -delete || die
+	einstalldocs
+}