1 files changed, 114 insertions, 0 deletions
diff --git a/net-misc/chrony/chrony-2.2-r1.ebuild b/net-misc/chrony/chrony-2.2-r1.ebuild
new file mode 100644
index 000000000000..04ce021eb38e
--- /dev/null
+++ b/net-misc/chrony/chrony-2.2-r1.ebuild
@@ -0,0 +1,114 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit eutils systemd toolchain-funcs
+
+DESCRIPTION="NTP client and server programs"
+HOMEPAGE="http://chrony.tuxfamily.org/"
+SRC_URI="http://download.tuxfamily.org/${PN}/${P/_/-}.tar.gz"
+LICENSE="GPL-2"
+SLOT="0"
+
+KEYWORDS="~amd64 ~arm ~hppa ~mips ~ppc ~ppc64 ~sparc ~x86"
+IUSE="caps +cmdmon ipv6 libedit +ntp +phc +pps readline +refclock +rtc selinux +adns"
+REQUIRED_USE="
+	?? ( libedit readline )
+"
+
+CDEPEND="
+	caps? ( sys-libs/libcap )
+	libedit? ( dev-libs/libedit )
+	readline? ( >=sys-libs/readline-4.1-r4:= )
+"
+DEPEND="
+	${CDEPEND}
+	sys-apps/texinfo
+"
+RDEPEND="
+	${CDEPEND}
+	selinux? ( sec-policy/selinux-chronyd )
+"
+
+RESTRICT=test
+
+S="${WORKDIR}/${P/_/-}"
+
+src_prepare() {
+	sed -i \
+		-e 's:/etc/chrony\.:/etc/chrony/chrony.:g' \
+		-e 's:/var/run:/run:g' \
+		conf.c chrony.texi.in examples/* || die
+}
+
+src_configure() {
+	tc-export CC
+
+	local CHRONY_EDITLINE
+	# ./configure legend:
+	# --disable-readline : disable line editing entirely
+	# --without-readline : do not use sys-libs/readline (enabled by default)
+	# --without-editline : do not use dev-libs/libedit (enabled by default)
+	if ! use readline && ! use libedit; then
+		CHRONY_EDITLINE='--disable-readline'
+	else
+		CHRONY_EDITLINE+=" $(usex readline '' --without-readline)"
+		CHRONY_EDITLINE+=" $(usex libedit '' --without-editline)"
+	fi
+
+	# not an autotools generated script
+	local CHRONY_CONFIGURE="
+	./configure \
+		$(usex caps '' --disable-linuxcaps) \
+		$(usex cmdmon '' --disable-cmdmon) \
+		$(usex ipv6 '' --disable-ipv6) \
+		$(usex ntp '' --disable-ntp) \
+		$(usex phc '' --disable-phc) \
+		$(usex pps '' --disable-pps) \
+		$(usex rtc '' --disable-rtc) \
+		$(usex refclock '' --disable-refclock) \
+		$(usex adns '' --disable-asyncdns) \
+		${CHRONY_EDITLINE} \
+		${EXTRA_ECONF} \
+		--docdir=/usr/share/doc/${PF} \
+		--chronysockdir=/run/chrony \
+		--infodir=/usr/share/info \
+		--mandir=/usr/share/man \
+		--prefix=/usr \
+		--sysconfdir=/etc/chrony \
+		--disable-sechash \
+		--without-nss \
+		--without-tomcrypt
+	"
+
+	# print the ./configure call to aid in future debugging
+	einfo ${CHRONY_CONFIGURE}
+	bash ${CHRONY_CONFIGURE} || die
+}
+
+src_compile() {
+	emake all docs
+}
+
+src_install() {
+	default
+
+	doinfo chrony.info*
+
+	newinitd "${FILESDIR}"/chronyd.init-r1 chronyd
+	newconfd "${FILESDIR}"/chronyd.conf chronyd
+
+	insinto /etc/${PN}
+	newins examples/chrony.conf.example1 chrony.conf
+
+	dodoc examples/*.example*
+
+	keepdir /var/{lib,log}/chrony
+
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}"/chrony-2.2.logrotate chrony
+
+	systemd_newunit "${FILESDIR}"/chronyd.service-r2 chronyd.service
+	systemd_enable_ntpunit 50-chrony chronyd.service
+}