1 files changed, 33 insertions, 0 deletions
diff --git a/sci-libs/openlibm/openlibm-0.8.0.ebuild b/sci-libs/openlibm/openlibm-0.8.0.ebuild
new file mode 100644
index 000000000000..ba45cbd625fb
--- /dev/null
+++ b/sci-libs/openlibm/openlibm-0.8.0.ebuild
@@ -0,0 +1,33 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+DESCRIPTION="High quality system independent, open source libm"
+HOMEPAGE="https://github.com/JuliaLang/openlibm"
+SRC_URI="https://github.com/JuliaMath/openlibm/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="public-domain MIT ISC BSD-2 LGPL-2.1+"
+# See https://abi-laboratory.pro/index.php?view=timeline&l=openlibm
+SLOT="0/4"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+
+src_prepare() {
+	default
+	sed -e "/^OLM_LIBS :=/s/^/#/" \
+		-e "/install: /s/install-static//" \
+	-i Makefile || die
+}
+
+src_configure() {
+	tc-export CC CXX FC AR LD
+	default
+}
+
+src_install() {
+	emake DESTDIR="${D}" prefix="${EPREFIX}/usr" \
+		libdir="${EPREFIX}/usr/$(get_libdir)" install
+	dodoc README.md
+}