1 files changed, 47 insertions, 0 deletions
diff --git a/sci-mathematics/jags/jags-4.3.0.ebuild b/sci-mathematics/jags/jags-4.3.0.ebuild
new file mode 100644
index 000000000000..0a07a6aa6740
--- /dev/null
+++ b/sci-mathematics/jags/jags-4.3.0.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs
+
+MYP="JAGS-${PV}"
+
+DESCRIPTION="Just Another Gibbs Sampler for Bayesian MCMC simulation"
+HOMEPAGE="https://mcmc-jags.sourceforge.io/"
+SRC_URI="mirror://sourceforge/project/mcmc-jags/JAGS/4.x/Source/${MYP}.tar.gz"
+
+SLOT="0"
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc"
+
+RDEPEND="
+	virtual/blas
+	virtual/lapack
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	doc? (
+		virtual/latex-base
+		dev-texlive/texlive-latexextra
+	)"
+
+S="${WORKDIR}/${MYP}"
+
+src_configure() {
+	econf \
+		--with-blas="$($(tc-getPKG_CONFIG) --libs blas)" \
+		--with-lapack="$($(tc-getPKG_CONFIG) --libs lapack)"
+}
+
+src_compile() {
+	emake all $(usex doc docs "")
+}
+
+src_install() {
+	default
+	use doc && dodoc doc/manual/*.pdf
+	find "${ED}" -name '*.la' -delete || die
+}