2 files changed, 111 insertions, 0 deletions
diff --git a/www-client/opera/Manifest b/www-client/opera/Manifest
index 28d00b5fc43d..c89c0c3f9c08 100644
--- a/www-client/opera/Manifest
+++ b/www-client/opera/Manifest
@@ -1 +1,2 @@
 DIST opera-stable_70.0.3728.154_amd64.deb 67310968 BLAKE2B e43b41be25dfda3079d2c57c1a9b9df54ff5d27c689fe42efc507a7f979d0ff2a828032bd3d149ab72856d07547f19a1fc625565dee11835734a4061403c7272 SHA512 d708e96be745693de15a23b03716ba77430cc1feeaf56f85ba35dc9b537261a92bc1749d363ed0fba6600810a12e6d470f208c472fee116f6a3f0e100b3ad957
+DIST opera-stable_70.0.3728.178_amd64.deb 67334984 BLAKE2B 5cc3bfdaa19f948eec19ca69af6023526d126e31d8d5c5869f2c86fa63d834c72ca82e6982c57984af531450ed1fc243c7dbae0b2f36d752210aa195570dc660 SHA512 22fbde279f97b7c619621713f980385951abf682f4d38aa63905b5a1f5127a58f3955b4f2d9076c2d82f3dadb2103027fb3f226469226e4b0ad7b438a3bb8169
diff --git a/www-client/opera/opera-70.0.3728.178.ebuild b/www-client/opera/opera-70.0.3728.178.ebuild
new file mode 100644
index 000000000000..58c0be89c0ab
--- /dev/null
+++ b/www-client/opera/opera-70.0.3728.178.ebuild
@@ -0,0 +1,110 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+CHROMIUM_LANGS="
+	be bg bn ca cs da de el en-GB en-US es-419 es fil fi fr-CA fr hi hr hu id
+	it ja ko lt lv ms nb nl pl pt-BR pt-PT ro ru sk sr sv sw ta te th tr uk vi
+	zh-CN zh-TW
+
+"
+inherit chromium-2 multilib unpacker xdg-utils
+
+DESCRIPTION="A fast and secure web browser"
+HOMEPAGE="https://www.opera.com/"
+LICENSE="OPERA-2014"
+SLOT="0"
+SRC_URI_BASE="
+	https://download1.operacdn.com/pub/
+	https://download2.operacdn.com/pub/
+	https://download3.operacdn.com/pub/
+	https://download4.operacdn.com/pub/
+"
+for uri in ${SRC_URI_BASE}; do
+SRC_URI+="
+	"${uri}${PN}/desktop/${PV}/linux/${PN}-stable_${PV}_amd64.deb"
+"
+done
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	media-libs/alsa-lib
+	media-libs/fontconfig
+	media-libs/freetype
+	net-misc/curl
+	net-print/cups
+	sys-apps/dbus
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3
+	x11-libs/libX11
+	x11-libs/libXScrnSaver
+	x11-libs/libXcomposite
+	x11-libs/libXcursor
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXi
+	x11-libs/libXrandr
+	x11-libs/libXrender
+	x11-libs/libXtst
+	x11-libs/libnotify
+	x11-libs/pango[X]
+"
+
+QA_PREBUILT="*"
+S=${WORKDIR}
+
+src_unpack() {
+	unpack_deb ${A}
+}
+
+src_prepare() {
+	default
+
+	OPERA_HOME="usr/$(get_libdir)/${PN}"
+
+	case ${ARCH} in
+		amd64)
+			mv usr/lib/x86_64-linux-gnu usr/$(get_libdir) || die
+			rm -r usr/lib || die
+			;;
+	esac
+
+	rm usr/bin/${PN} || die
+
+	rm usr/share/doc/${PN}-stable/copyright || die
+	mv usr/share/doc/${PN}-stable usr/share/doc/${PF} || die
+	gunzip usr/share/doc/${PF}/changelog.gz || die
+
+	pushd "${OPERA_HOME}"/localization > /dev/null || die
+	chromium_remove_language_paks
+	popd > /dev/null || die
+
+	sed -i \
+		-e 's|^TargetEnvironment|X-&|g' \
+		usr/share/applications/${PN}.desktop || die
+}
+
+src_install() {
+	rm "${OPERA_HOME}"/${PN}_autoupdate || die
+	mv * "${D}" || die
+	dosym ../$(get_libdir)/${PN}/${PN} /usr/bin/${PN}
+	fperms 4711 /"${OPERA_HOME}"/opera_sandbox
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+}